simon-with-score.ino Copy - Wokwi ESP32, STM32, Arduino Simulator

https://www.tickettailor.com/events/alienromulusfullhd
https://www.tickettailor.com/events/watchalienromulusfullmovie1
https://www.tickettailor.com/events/watchfreealienromulus
https://www.tickettailor.com/events/alienromulusonlinestreaming
https://www.tickettailor.com/events/alienromulusstreamingathome
https://www.tickettailor.com/events/alienromulushdstreamings
https://www.tickettailor.com/events/thecrowfullmovie
https://www.tickettailor.com/events/watchthecrowfullmovie
https://www.tickettailor.com/events/thecrowfullmoviedownload
https://www.tickettailor.com/events/thecrowstreamingathome
https://www.tickettailor.com/events/thecrowonlinestreaming
https://www.tickettailor.com/events/thecrowfullmovieusa01
https://www.tickettailor.com/events/siddharthroyhindidubbed
https://www.tickettailor.com/events/siddharthroyfulldownload
https://www.tickettailor.com/events/siddharthroyhdstreaming
https://www.tickettailor.com/events/alienromulusfilmecompleto1
https://www.tickettailor.com/events/superflixalienromulusfilmecompleto
https://www.tickettailor.com/events/assistiralienromuluscompleto
https://www.tickettailor.com/events/assistiralienromulus2024
https://www.tickettailor.com/events/assistirhdalienromulusdublado
https://web.stanford.edu/group/spanlab/cgi-bin/wiki/index.php?title=User_talk:180.252.20.112
https://ybclassifieds.com/index.php?page=item&id=18689
https://worldfreeclassifiedads.com/classes/music-theatre-dance-classes/google_i23593
https://marketadclassifieds.com/classes/music-theatre-dance-classes/google_i30875
https://classifiedadwebsite.com/classes/music-theatre-dance-classes/google_i24976
https://affiliateclassifiedads.com/business-opportunities_2/publishing/google_i73072
https://groovyfreeads.com/business-opportunities_2/general/google_i301898
https://promohubspotlight.com/classes/tutoring-private-lessons/google_i21052
https://communicators.ncsu.edu/forum/google
https://tic-tac.teleco.uvigo.es/forum/google
https://cofradesdegranada.ideal.es/members/grecenine
https://community.thoracic.org/members/grecenine
https://community.goldencorral.com/members/chevaanindya
https://rentry.co/inh88ap7
https://pastelink.net/oyx2gu13
https://jsfiddle.net/alva12345/c7q9afgm/
https://rextester.com/SBR2949
https://telegra.ph/Google-08-22-4
https://www.wowace.com/paste/7244bc8a
https://wow.curseforge.com/paste/b7863493
https://dev.bukkit.org/paste/a5a2cc19
https://authors-old.curseforge.com/paste/b027f052
https://rift.curseforge.com/paste/440e2294
https://paste.feed-the-beast.com/view/1fe9775a
/**
   Simon Game for Arduino with Score display

   Copyright (C) 2022, Uri Shaked

   Released under the MIT License.
*/

#include "pitches.h"

/* Constants - define pin numbers for LEDs,
   buttons and speaker, and also the game tones: */
const uint8_t ledPins[] = {9, 10, 11, 12};
const uint8_t buttonPins[] = {2, 3, 4, 5};
#define SPEAKER_PIN 8

// These are connected to 74HC595 shift register (used to show game score):
const int LATCH_PIN = A1;  // 74HC595 pin 12
const int DATA_PIN = A0;  // 74HC595pin 14
const int CLOCK_PIN = A2;  // 74HC595 pin 11

#define MAX_GAME_LENGTH 100

const int gameTones[] = { NOTE_G3, NOTE_C4, NOTE_E4, NOTE_G5};

/* Global variables - store the game state */
uint8_t gameSequence[MAX_GAME_LENGTH] = {0};
uint8_t gameIndex = 0;

/**
   Set up the Arduino board and initialize Serial communication
*/
void setup() {
  Serial.begin(9600);
  for (byte i = 0; i < 4; i++) {
    pinMode(ledPins[i], OUTPUT);
    pinMode(buttonPins[i], INPUT_PULLUP);
  }
  pinMode(SPEAKER_PIN, OUTPUT);
  pinMode(LATCH_PIN, OUTPUT);
  pinMode(CLOCK_PIN, OUTPUT);
  pinMode(DATA_PIN, OUTPUT);

  // The following line primes the random number generator.
  // It assumes pin A3 is floating (disconnected):
  randomSeed(analogRead(A3));
}

/* Digit table for the 7-segment display */
const uint8_t digitTable[] = {
  0b11000000,
  0b11111001,
  0b10100100,
  0b10110000,
  0b10011001,
  0b10010010,
  0b10000010,
  0b11111000,
  0b10000000,
  0b10010000,
};
const uint8_t DASH = 0b10111111;

void sendScore(uint8_t high, uint8_t low) {
  digitalWrite(LATCH_PIN, LOW);
  shiftOut(DATA_PIN, CLOCK_PIN, MSBFIRST, low);
  shiftOut(DATA_PIN, CLOCK_PIN, MSBFIRST, high);
  digitalWrite(LATCH_PIN, HIGH);
}

void displayScore() {
  int high = gameIndex % 100 / 10;
  int low = gameIndex % 10;
  sendScore(high ? digitTable[high] : 0xff, digitTable[low]);
}

/**
   Lights the given LED and plays a suitable tone
*/
void lightLedAndPlayTone(byte ledIndex) {
  digitalWrite(ledPins[ledIndex], HIGH);
  tone(SPEAKER_PIN, gameTones[ledIndex]);
  delay(300);
  digitalWrite(ledPins[ledIndex], LOW);
  noTone(SPEAKER_PIN);
}

/**
   Plays the current sequence of notes that the user has to repeat
*/
void playSequence() {
  for (int i = 0; i < gameIndex; i++) {
    byte currentLed = gameSequence[i];
    lightLedAndPlayTone(currentLed);
    delay(50);
  }
}

/**
    Waits until the user pressed one of the buttons,
    and returns the index of that button
*/
byte readButtons() {
  while (true) {
    for (byte i = 0; i < 4; i++) {
      byte buttonPin = buttonPins[i];
      if (digitalRead(buttonPin) == LOW) {
        return i;
      }
    }
    delay(1);
  }
}

/**
  Play the game over sequence, and report the game score
*/
void gameOver() {
  Serial.print("Game over! your score: ");
  Serial.println(gameIndex - 1);
  gameIndex = 0;
  delay(200);

  // Play a Wah-Wah-Wah-Wah sound
  tone(SPEAKER_PIN, NOTE_DS5);
  delay(300);
  tone(SPEAKER_PIN, NOTE_D5);
  delay(300);
  tone(SPEAKER_PIN, NOTE_CS5);
  delay(300);
  for (byte i = 0; i < 10; i++) {
    for (int pitch = -10; pitch <= 10; pitch++) {
      tone(SPEAKER_PIN, NOTE_C5 + pitch);
      delay(5);
    }
  }
  noTone(SPEAKER_PIN);

  sendScore(DASH, DASH);
  delay(500);
}

/**
   Get the user's input and compare it with the expected sequence.
*/
bool checkUserSequence() {
  for (int i = 0; i < gameIndex; i++) {
    byte expectedButton = gameSequence[i];
    byte actualButton = readButtons();
    lightLedAndPlayTone(actualButton);
    if (expectedButton != actualButton) {
      return false;
    }
  }

  return true;
}

/**
   Plays a hooray sound whenever the user finishes a level
*/
void playLevelUpSound() {
  tone(SPEAKER_PIN, NOTE_E4);
  delay(150);
  tone(SPEAKER_PIN, NOTE_G4);
  delay(150);
  tone(SPEAKER_PIN, NOTE_E5);
  delay(150);
  tone(SPEAKER_PIN, NOTE_C5);
  delay(150);
  tone(SPEAKER_PIN, NOTE_D5);
  delay(150);
  tone(SPEAKER_PIN, NOTE_G5);
  delay(150);
  noTone(SPEAKER_PIN);
}

/**
   The main game loop
*/
void loop() {
  displayScore();

  // Add a random color to the end of the sequence
  gameSequence[gameIndex] = random(0, 4);
  gameIndex++;
  if (gameIndex >= MAX_GAME_LENGTH) {
    gameIndex = MAX_GAME_LENGTH - 1;
  }

  playSequence();
  if (!checkUserSequence()) {
    gameOver();
  }

  delay(300);

  if (gameIndex > 0) {
    playLevelUpSound();
    delay(300);
  }
}