#include "DHTesp.h"
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // Largura do display, em pixels
#define SCREEN_HEIGHT 64 // Altura do display, em pixels
#define LDR_PIN 34 // Pino do LDR
#define DHT_PIN 33 // Pino do DHT

// LDR Characteristics
const float GAMMA = 0.7; // Parâmetro do LDR
const float RL10 = 33; // Resistência em 10 lux
int valorAnterior = 0; // Variável para armazenar o valor anterior
float lux = 0;

// Declaração do objeto display
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

DHTesp dhtSensor;

void setup() {
  Serial.begin(115200);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  Serial.println("Iniciando leitura do sensor de luminosidade...");

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Endereço 0x3C para o display 128x64
    Serial.println(F("SSD1306 Falha de Alocação I2C"));
    for (;;);
  }
}

void loop() {
  // Leitura da temperatura e umidade
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  Serial.println("Temp: " + String(data.temperature, 2) + "°C");
  Serial.println("Humidity: " + String(data.humidity, 1) + "%");

  // Leitura do LDR
  float iluminacao = fotoresistor(); // Chama a função para calcular a luminosidade
  Serial.println("Luminosidade (LDR): " + String(lux));
  Serial.println("---");

  // Limpa o display
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 10);

  // Mostra a temperatura e umidade no display
  display.print("Temp: ");
  display.print(data.temperature, 2);
  display.println(" °C");

  display.print("Umidade: ");
  display.print(data.humidity, 1);
  display.println(" %");

  // Mostra a luminosidade no display
  display.print("Luminosidade: ");
  display.print(lux);
  display.println(" LUX");

  // Mostra se o ambiente está claro ou escuro
  if (lux > 400) {
    display.println("Ambiente: Claro!");
  } else {
    display.println("Ambiente: Escuro");
  }

  // Atualiza o display
  display.display();

  delay(2000); // Atraso entre as leituras
}

float fotoresistor() {
  int analogValue = analogRead(LDR_PIN);
  
  // Só faz a leitura se houver uma alteração no valor
  if (analogValue != valorAnterior) {
    float voltage = analogValue / 4096.0 * 3.3; // Converte o valor analógico para tensão
    float resistance = 2000 * voltage / (1 - voltage / 3.3); // Calcula a resistência do LDR
    lux = pow(RL10 * 1e3 * pow(10, GAMMA) / resistance, (1 / GAMMA)); // Calcula a lux

    Serial.print("Ambiente: ");
    
    // Iluminação do escritório valor 400
    if (lux > 400) {
      Serial.println("Claro!");
    } else {
      Serial.println("Escuro");
    }

    Serial.print("Luminosidade: ");
    Serial.println(lux);

    valorAnterior = analogValue;
  }
  return lux;
}