// Configuración del DHT22
#include <DHT.h>
#define DHTPIN 25      // Pin al que está conectado el DATA del DHT22
#define DHTTYPE DHT22   // Definir el tipo de sensor DHT
DHT dht(DHTPIN, DHTTYPE);

// Configuración del WiFi
#include <WiFi.h>
#include <WiFiClientSecure.h>
const char* ssid = "Wokwi-GUEST";  // Nombre de la red WiFi en Wokwi
const char* password = "";         // Contraseña de WiFi (vacía para Wokwi-GUEST)
WiFiClientSecure espClient;  // Cliente seguro para TLS

// Configuración del MQTT
#include <PubSubClient.h>
const char* mqtt_server = "9273d8a235eb4892a476fe54152fe6b1.s1.eu.hivemq.cloud"; // La URL de tu broker
const int mqtt_port = 8883; // Puerto TLS
const char* mqtt_user = "angelurueta"; // Usuario del broker MQTT
const char* mqtt_password = "angelurueta"; // Contraseña del broker MQTT
PubSubClient client(espClient);

void setup() {
  Serial.begin(115200);
  dht.begin();

  // Conectar a WiFi
  setup_wifi();

  // Configurar el servidor MQTT
  espClient.setInsecure();  // Usar conexiones inseguras por ahora
  client.setServer(mqtt_server, mqtt_port);
}

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("Connected to WiFi");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  static unsigned long lastReconnectAttempt = 0;
  unsigned long now = millis();

  if (!client.connected()) {
    if (now - lastReconnectAttempt > 2000) { // Intentar reconectar cada 2 segundos
      lastReconnectAttempt = now;
      Serial.print("Attempting MQTT connection...");
      String clientID = "IOT_Grupo63_";
      clientID += String(random(0xffff), HEX);

      // Intentar conectar con el broker
      if (client.connect(clientID.c_str(), mqtt_user, mqtt_password)) {
        Serial.println("connected");
      } else {
        Serial.print("failed, rc=");
        Serial.print(client.state());
        Serial.println(" try again in 5 seconds");
      }
    }
  }
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  // Leer la humedad y la temperatura del DHT22
  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();

  // Verificar si la lectura falló y salir si es así
  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Publicar la lectura en el broker MQTT
  String payload = "Temperatura: " + String(temperature) + " °C, Humedad: " + String(humidity) + " %";
  String payload2 = String(temperature);
  String payload3 = String(humidity);
  //Mostrar mensaje
  Serial.println(payload);

  String topic = String(mqtt_user) + "/sensor/topic";
  String topic2 = String(mqtt_user) + "/sensor/temp";
  String topic3 = String(mqtt_user) + "/sensor/hum";

  // Publicar el mensaje con el flag de retain (retener)
  client.publish(topic.c_str(), payload.c_str(), true); 
  client.publish(topic2.c_str(), payload2.c_str(), true);
  client.publish(topic3.c_str(), payload3.c_str(), true);

  // Esperar 5 segundos antes de leer de nuevo
  delay(5000);
}