#include <WiFi.h>
#include <PubSubClient.h>
#include "DHT.h"

#define PIR_PIN 28
#define DHTPIN 18
#define DHTTYPE DHT22

DHT dht(DHTPIN, DHTTYPE);

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.hivemq.com";

WiFiClient espClient;
PubSubClient client(espClient);

int lastState = LOW;

// ===== WIFI =====
void setup_wifi() {
  Serial.print("Connecting WiFi");

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWiFi connected!");
}

// ===== MQTT =====
void reconnect() {
  while (!client.connected()) {
    Serial.print("Connecting MQTT...");

    if (client.connect("pico_out")) {
      Serial.println("OK");
    } else {
      Serial.print("FAILED, rc=");
      Serial.print(client.state());
      Serial.println(" retry...");
      delay(1000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(PIR_PIN, INPUT);
  dht.begin();

  setup_wifi();

  client.setServer(mqtt_server, 1883);
}

void loop() {
  if (!client.connected()) reconnect();
  client.loop();

  // ===== PIR =====
  int val = digitalRead(PIR_PIN);

  if (val == HIGH && lastState == LOW) {
    Serial.println("PIR triggered → gate/out");
    client.publish("gate/out", "1");
    delay(1000);
  }

  lastState = val;

  // ===== DHT =====
  float t = dht.readTemperature();
  float h = dht.readHumidity();

  if (isnan(t) || isnan(h)) {
    Serial.println("DHT read FAILED");
  } else {
    String payload = "{";
    payload += "\"temp\":" + String(t) + ",";
    payload += "\"hum\":" + String(h);
    payload += "}";

    Serial.print("Publishing sensor: ");
    Serial.println(payload);

    client.publish("sensor/data", payload.c_str());
  }

  delay(3000);
}