#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <NewPing.h>

#define DHTPIN 4
#define DHTTYPE DHT22
#define TRIG_PIN 5
#define ECHO_PIN 18
#define LED_PIN 2

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.hivemq.com";

WiFiClient espClient;
PubSubClient client(espClient);

DHT dht(DHTPIN, DHTTYPE);
NewPing sonar(TRIG_PIN, ECHO_PIN, 200);

unsigned long lastMsg = 0;

void callback(char* topic, byte* payload, unsigned int length) {
  String messageTemp;

  for (int i = 0; i < length; i++) {
    messageTemp += (char)payload[i];
  }

  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("]: ");
  Serial.println(messageTemp);

  if (String(topic) == "esp32/control/led") {
    if (messageTemp == "ON") {
      digitalWrite(LED_PIN, HIGH);
      Serial.println("LED Turned ON");
    } 
    else if (messageTemp == "OFF") {
      digitalWrite(LED_PIN, LOW);
      Serial.println("LED Turned OFF");
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");

    String clientId = "ESP32Client-Wokwi-" + String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      client.subscribe("esp32/control/led");
    } 
    else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);

  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);

  dht.begin();

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWiFi connected - Wokwi-GUEST");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }

  client.loop();

  unsigned long now = millis();

  if (now - lastMsg > 4000) {
    lastMsg = now;

    float h = dht.readHumidity();
    float t = dht.readTemperature();
    int distance = sonar.ping_cm();

    if (!isnan(t) && !isnan(h)) {
      char payload[150];

      snprintf(
        payload,
        sizeof(payload),
        "{\"temperature\":%.2f,\"humidity\":%.2f,\"distance\":%d}",
        t, h, distance
      );

      client.publish("esp32/sensor/data", payload);

      Serial.print("Published: ");
      Serial.println(payload);
    } 
    else {
      Serial.println("Failed to read from DHT sensor!");
    }
  }
}