/*

  Simon! in AVR assembly

  ┍━━━━━━━━━━━━━━━━━━━━━━━━┑
  │	Take a look at simon.S │
  ┕━━━━━━━━━━━━━━━━━━━━━━━━┙

*/

simon-asm.ino

Simon is a simple electronic memory game: the user has to repeat a growing sequence of
colors. The sequence is displayed by lighting up the LEDs. Each color also has a
corresponding tone.

In each turn, the game will play the sequence, and then wait for the user to repeat
the sequence by pressing the buttons according to the color sequence. If the user
repeated the sequence correctly, the game will play a "leveling-up" sound, add a new
color at the end of the sequence, and move to the next turn.

The game continues until the user has made a mistake. Then a game over sound is
played, and the game restarts.

![Simon Game Shield for Arduino Uno](https://i.imgur.com/CBVsVxzh.jpg)

### Hardware

| Item             | Quantity | Notes                        |
| ---------------- | -------- | ---------------------------- |
| Arduino Uno R3   | 1        |                              |
| 5mm LED          | 4        | Red, Green, Blue, and Yellow |
| 12mm Push button | 4        | Red, Green, Blue, and Yellow |
| Resistor         | 4        | 220Ω                         |
| Piezo Buzzer     | 1        |                              |

### Pin Connections

| Arduino Pin | Device        |
| ----------- | ------------- |
| 12          | Red LED       |
| 11          | Green LED     |
| 10          | Blue LED      |
| 9           | Yellow LED    |
| 8           | Buzzer        |
| 5           | Red Button    |
| 4           | Green Button  |
| 3           | Blue Button   |
| 2           | Yellow Button |

- The LEDs are connected through a 220Ω resistor each.


README.md

#define __SFR_OFFSET 0

#include "avr/io.h"

.global main 
.global __do_copy_data

.data
seq_index: .byte 0
sequence:  .space 32

.text

gpio_init:
  ser r18
  out DDRB, r18   ; set pins 8...13 to output
  out PORTD, r18  ; set pins 0...7  to input
  ret

timer_init:
  ldi r18, 1 << CS01
  out TCCR0B, r18
  ret

; delay for the given number of millis (given in r25:24)
delay_ms:
  ldi r26, lo8(4000)
  ldi r27, hi8(4000)
.wait_loop:
  sbiw r26, 1 
  brne .wait_loop
  sbiw r24, 1
  brne delay_ms
  ret

read_key:
  in r18, PIND
  com r18
  andi r18, (1 << PB2) | (1 << PB3) | (1 << PB4) | (1 << PB5)
  breq read_key
  clr r24
  sbrc r18, PB2
  jmp 1f
  inc r24
  sbrc r18, PB3
  jmp 1f
  inc r24
  sbrc r18, PB4
  jmp 1f
  inc r24
1: 
  ret

extend_sequence:
  lds r18, seq_index
  ldi r30, lo8(sequence)
  ldi r31, hi8(sequence)
  add r30, r18
  adc r31, r1
  in  r19, TCNT0
  andi r19, 0x3
  st  Z, r19
  inc r18
  sts seq_index, r18
  ret

; led index in r24 (0..3)
light_led:
  cpi r24, 0
  brne .+2
  sbi PORTB, PB1
  cpi r24, 1
  brne .+2
  sbi PORTB, PB2
  cpi r24, 2
  brne .+2
  sbi PORTB, PB3
  cpi r24, 3
  brne .+2
  sbi PORTB, PB4
  ldi r24, lo8(300)
  ldi r25, hi8(300)
  call delay_ms
  out PORTB, r1
  ret

play_sequence:
  push r15
  clr r15
  ldi r30, lo8(sequence)
  ldi r31, hi8(sequence)
1:
  lds r18, seq_index
  cp  r18, r15
  breq 2f
  ld  r24, Z+
  call light_led
  ldi r24, 100
  clr r25
  call delay_ms
  inc r15
  jmp 1b
2:
  pop r15
  ret

test_sequence:
  push r15
  push r14
  clr r15
  ldi r30, lo8(sequence)
  ldi r31, hi8(sequence)
1:
  lds r18, seq_index
  cp  r18, r15
  breq 2f
  call read_key
  mov r14, r24
  call light_led
  ld  r24, Z+
  cp  r14, r24
  brne game_over
  inc r15
  jmp 1b
game_over:
  sts seq_index, r1
2:
  pop r14
  pop r15
  ret

game_loop:
  call extend_sequence
  call play_sequence
  call test_sequence
  ldi r24, lo8(500)
  ldi r25, hi8(500)
  call delay_ms
  jmp game_loop

main:
  call gpio_init
  call timer_init
  call read_key
  call game_loop

1:
  jmp 1b

