#include <Button.h>

// all the physical connection of the push button, loads and FLS

const int tank1Pin = 4;
const int tank2Pin = 5;
const int buttonPin = 9;
const int ledButtonPin = 10;
const int flowPin = 3;

const unsigned long TANK1_MAX = 5;    // capacity of maximum mL tank1_max
const unsigned long TANK2_MAX = 7;    // capacity of maximum mL tank2_max

typedef enum {
  IDLE,
  TANK1,
  TANK2
} MachineState;
MachineState state = IDLE;

volatile unsigned long pulseCounter;          // this integer needs to be set as volatile to ensure it updates correctly during the interrupt process.

Button button(buttonPin);

//========================================

void setup() {
  Serial.begin(9600);
  Serial.println("Machine started");       // so we know what sketch is running

  button.begin();
  pinMode(tank1Pin, OUTPUT);
  pinMode(tank2Pin, OUTPUT);
  pinMode(ledButtonPin, OUTPUT);

  pinMode(flowPin, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(flowPin), isrCount, RISING);     // interrupt programme when signal to pin 3 detected (1 = pin 3)
}

//========================================

void stopMachine() {
  Serial.println("Stopping machine");
  noInterrupts();
  digitalWrite(tank1Pin, LOW);
  digitalWrite(tank2Pin, LOW);
  digitalWrite(ledButtonPin, LOW);
  state = IDLE;
  interrupts();
}

void fillTank1() {
  Serial.println("Filling tank 1");
  noInterrupts();
  digitalWrite(ledButtonPin, HIGH);
  digitalWrite(tank1Pin, HIGH);
  state = TANK1;
  pulseCounter = 0;
  interrupts();
}

void fillTank2() {
  Serial.println("Filling tank 2");
  noInterrupts();
  digitalWrite(tank1Pin, LOW);
  digitalWrite(tank2Pin, HIGH);
  state = TANK2;
  pulseCounter = 0;
  interrupts();
}

void loop() {
  bool buttonDown = button.pressed();

  switch (state) {
    case IDLE:
      if (buttonDown) {
        fillTank1();
      }
      break;

    case TANK1:
      if (buttonDown) {
        stopMachine();
      } else if (pulseCounter == TANK1_MAX) {
        fillTank2();
      }
      break;

    case TANK2:
      if (buttonDown || pulseCounter == TANK2_MAX) {
        stopMachine();
      }
      break;
  }
}

void isrCount() {
  pulseCounter++;
}