/* A program that measures the temperature using a temperature sensor every 5 
seconds while simultaneously generating a tune with varying pitches every 2 seconds from 
the speaker. You are required to display values of temperature at each time of measurement 
and the text “Speaker is on!” right before a tune is generated and the text “Speaker if off!” 
right after the tune is turned off. */

/* Notes:
The TMP sensor returns an analogue signal which we need to calibrate. 
The sensor is sensitive to temperature and its impedance, hence voltage 
across will vary in relation to temperature changes in its immediate 
surrounding. We thus need to first convert the raw reading into a voltage, 
and then adding the intercept and timing it by the gradient that can be 
found on the relevant datasheet to get the temperature reading.  

In code, the temperature of the NTC thermistor is calculated by using the Steinhart–Hart equation. 
It is considered the best mathematical expression to obtain the resistance vs temperature characteristic 
of an NTC thermistor. It can obtain the temperature values that are approximately equal to the actual values 
from the instantaneous resistance of the thermistor.

References: https://mechatrofice.com/arduino/measure-temperature-arduino-ntc-thermistor
            https://www.youtube.com/watch?v=hD3cR25MbW8
*/
#include "pitches.h"

const int BUZZER_PIN = 7;

const float BETA = 3950; // should match the Beta Coefficient of the thermistor
const float TEMP_NOMINAL = 298.15; // nominal temperature

// Timed events constants in ms
const unsigned long TONE_EVENT_TIME_1 = 2000;
const unsigned long TEMP_EVENT_TIME_2 = 5000;

unsigned long previousTime_1 = 0;
unsigned long previousTime_2 = 0;


void setup() {
  // initialize serial communication
  Serial.begin(9600);

  // sets the pin as output
  pinMode(BUZZER_PIN, OUTPUT); 
}

void loop() {
  // get the updated time - updates frequently
  unsigned long currentTime = millis();

  // Event 1 - buzzer/tone
  // if the difference between the current and previous time is more than the
  // event time, then it is time to play the tone.
  if(currentTime - previousTime_1 >= TONE_EVENT_TIME_1) {
    //Serial.println(currentTime);
    playTone();

    // Update timing for the next event
    previousTime_1 = currentTime;
  }

  // Event 2 - read and display temp
  // if the difference between the current and previous time is more than the
  // event time, then it is time to read/display temp.
  if(currentTime - previousTime_2 >= TEMP_EVENT_TIME_2) {
    //Serial.println(currentTime);
    displayTemp();

    // Update timing for the next event
    previousTime_2 = currentTime;
  }
}


/* Plays a music tone with varying pitches */
void playTone() {
  Serial.println("Speaker is on!");
  //tone(pin, frequency, duration)
  tone(BUZZER_PIN, NOTE_E4);
  delay(150);
  tone(BUZZER_PIN, NOTE_G4);
  delay(150);
  tone(BUZZER_PIN, NOTE_E5);
  delay(150);
  tone(BUZZER_PIN, NOTE_C5);
  delay(150);
  tone(BUZZER_PIN, NOTE_D5);
  delay(150);
  tone(BUZZER_PIN, NOTE_G5);
  delay(150);
  noTone(BUZZER_PIN);
  Serial.println("Speaker is off!");
}

void displayTemp() {
  // read the analog output of the sensor
  int analogValue = analogRead(A0);
  
  // calculate temp value in kelvin
  float kelvin = 1 / (log(1 / (1023. / analogValue - 1)) / BETA + 1.0 / TEMP_NOMINAL);
  
  // convert to celsius
  float celsius = kelvin - 273.15;

  // print results
  Serial.println((String)"Temperature in celsius    :" + celsius + "°C");
}