/*
  Blink without Delay Switch

  Turns on and off a light emitting diode (LED) connected to a digital pin,
  without using the delay() function. This means that other code can run at the
  same time without being interrupted by the LED code.

  The circuit:
  - Use the onboard LED. 
  - Note: Most Arduinos have an on-board LED you can control. On the UNO, MEGA
    and ZERO it is attached to digital pin 13, on MKR1000 on pin 6. LED_BUILTIN
    is set to the correct LED pin independent of which board is used.
    If you want to know what pin the on-board LED is connected to on your
    Arduino model, check the Technical Specs of your board at:
    https://www.arduino.cc/en/Main/Products

  created 2005
  by David A. Mellis
  modified 8 Feb 2010
  by Paul Stoffregen
  modified 11 Nov 2013
  by Scott Fitzgerald
  modified 9 Jan 2017
  by Arturo Guadalupi

  This example code is in the public domain.

  Based on:
  https://www.arduino.cc/en/Tutorial/BuiltInExamples/BlinkWithoutDelay
  Demo: https://wokwi.com/projects/325771523077964370

  Modified by DaveX per https://forum.arduino.cc/t/i-need-help-about-jumping-from-delay-to-multitasking/967874
  with: 
     1) if(ledState ... to switch(ledState) 
     2) variable intervals

  Demo: https://wokwi.com/projects/325773202843238994 BlinkWithoutDelaySwitch.ino
  Simpler: https://wokwi.com/projects/325771523077964370 BlinkWithoutDelay.ino
  More complicated: https://wokwi.com/projects/325783689645523538 BlinkWithoutDelaySwitchStates.ino

  */

// constants won't change. Used here to set a pin number:
const int ledPin =  LED_BUILTIN;// the number of the LED pin

// Variables will change:
int ledState = LOW;             // ledState used to set the LED
long interval = 1000;           // interval at which to blink (milliseconds)

// Generally, you should use "unsigned long" for variables that hold time
// The value will quickly become too large for an int to store
unsigned long previousMillis = 0;        // will store last time LED was updated

// constants won't change:
const long onInterval = 1000;           // interval at which to blink (milliseconds)
const long offInterval = 200;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the difference
  // between the current time and last time you blinked the LED is bigger than
  // the interval at which you want to blink the LED.
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;

    // if the LED is off turn it on and vice-versa:
    switch(ledState){
      case LOW: 
        ledState = HIGH;
        interval = onInterval;
        break;
      case HIGH:
        ledState = LOW;
        interval = offInterval;
        break;
    }

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
}