#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Fonts/FreeSansBold9pt7b.h> //setting jenis font yang digunakan
#include <Fonts/Picopixel.h> //setting jenis font yang digunakan

#define ENCODER_CLK 2
#define ENCODER_DT  3
#define ENCODER_SW  4

uint8_t volume = 50; //nilai awal dari volume, bisa diganti-ganti dengan nilai lainnya
uint8_t bass = 25; //nilai awal dari bass
uint8_t treble = 66; //nilai awal dari treble

typedef enum { //mode yang dapat diubah-ubah, bisa ditambah bisa dikurangi sesuai keinginan, nanti akan berpengaruh pada bagian case di perintah switch
  SET_VOLUME,
  SET_BASS,
  SET_TREBLE,
} Mode;

Mode mode = SET_VOLUME;

Adafruit_SSD1306 display(128, 64, &Wire, -1);

void nextMode() { //bagian untuk memindahkan mode menggunakan perintah switch
  switch (mode) {
    case SET_VOLUME:
      mode = SET_BASS;
      break;

    case SET_BASS:
      mode = SET_TREBLE;
      break;

    case SET_TREBLE:
      mode = SET_VOLUME;
      break;
  }
}

void updateValue(int delta) { //bagian untuk mengganti value dari variabel volume, bass, dan treble
  switch (mode) {
    case SET_VOLUME:
      volume = constrain(volume + delta, 0, 100); //nilai volume dari rentang 0-100, ditambahkan dengan nilai delta pada bagian void loop
      break;

    case SET_BASS:
      bass = constrain(bass + delta, 0, 100); //nilai bass dari rentang 0-100, ditambahkan dengan nilai delta pada bagian void loop
      break;

    case SET_TREBLE:
      treble = constrain(treble + delta, 0, 100); //nilai treble dari rentang 0-100, ditambahkan dengan nilai delta pada bagian void loop, rentangnya bisa diubah-ubah dengan mengganti nila 0 atau 100, 0 untuk nilai mimal, 100 nilai maksimal
      break;
  }
} //rentangnya bisa diubah-ubah dengan mengganti nila 0 atau 100, 0 untuk nilai mimal, 100 nilai maksimal

void updateDisplay() { //bagian untuk menampilkan data ke oled
  display.clearDisplay();
  display.setFont();
  display.setTextColor(1);

  display.setCursor(42, 2);
  display.print("Volume");
  display.drawRoundRect(10, 12, 102, 9, 2, WHITE);
  display.fillRect(11, 13, volume, 7, WHITE);
  if (mode == SET_VOLUME) {
    display.setCursor(32, 2);
    display.print(">");
  }

  display.setCursor(48, 22);
  display.print("Bass");
  display.drawRoundRect(10, 32, 102, 9, 2, WHITE);
  display.fillRect(11, 33, bass, 7, WHITE);
  if (mode == SET_BASS) {
    display.setCursor(38, 22);
    display.print(">");
  }

  display.setCursor(42, 42);
  display.print("Treble");
  display.drawRoundRect(10, 52, 102, 9, 2, WHITE);
  display.fillRect(11, 53, treble, 7, WHITE);
  if (mode == SET_TREBLE) {
    display.setCursor(32, 42);
    display.print(">");
  }

  display.display();
}

void setup() {
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C); //bisa juga alamat 0x3D
  pinMode(ENCODER_CLK, INPUT);
  pinMode(ENCODER_DT, INPUT);
  pinMode(ENCODER_SW, INPUT_PULLUP);
  updateDisplay();
}

long int modeLastChanged = 0;
int prevClk = HIGH;
void loop() {
  if (digitalRead(ENCODER_SW) == LOW && millis() - modeLastChanged > 300) {
    modeLastChanged = millis();
    nextMode();
    updateDisplay();
  }

  int clk = digitalRead(ENCODER_CLK);
  if (clk != prevClk && clk == LOW) {
    int dt = digitalRead(ENCODER_DT);
    int delta = dt == HIGH ? 5 : -5; //ternary operator untuk menambah nilainya antara 5 atau -5, bisa disesuaikan dengan setting penambahan kita
    updateValue(delta);
    updateDisplay();
  }
  prevClk = clk;
}