#include "WiFi.h"
#include "DHTesp.h"

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* thingSpeakAddress = "api.thingspeak.com";
const char* writeAPIKey = "AQ6H5U6CTDT9630D";
const char* fieldsuhu = "field1";
const char* fieldkelembaban = "field2";

WiFiClient client;
DHTesp dhtSensor;

void setup() {
  Serial.begin(9600);
  WiFi.disconnect();
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(300);
    Serial.print(".");
  }

  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  dhtSensor.setup(15, DHTesp::DHT22);
}

void loop() {
  delay(2000);

  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  float t = data.temperature;
  float h = data.humidity;

  if (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  sendToThingSpeak(t, h);
}

void sendToThingSpeak(float temperature, float humidity) {
  if (client.connect(thingSpeakAddress, 80)) {
    String request = "/update?";
    request += "key=";
    request += writeAPIKey;
    request += "&";
    request += fieldsuhu;
    request += "=";
    request += String(temperature);
    request += "&";
    request += fieldkelembaban;
    request += "=";
    request += String(humidity);

    Serial.println(String("GET ") + request + " HTTP/1.1\r\n" +
                 "Host: " + thingSpeakAddress + "\r\n" +
                 "Connection: close\r\n\r\n");

    client.print(String("GET ") + request + " HTTP/1.1\r\n" +
                 "Host: " + thingSpeakAddress + "\r\n" +
                 "Connection: close\r\n\r\n");

    unsigned long timeout = millis();
    while (client.available() == 0) {
      if (millis() - timeout > 5000) {
        Serial.println(">>> Client Timeout !");
        client.stop();
        return;
      }
    }

    while (client.available()) {
      String line = client.readStringUntil('\r');
      Serial.print(line);
    }

    Serial.println();
    Serial.println("Closing connection");
    client.stop();
  } else {
    Serial.println("Failed to connect to ThingSpeak server!");
  }
}