#include <DHTesp.h>         // deklarasi untuk emmanggil library dhtesp
#include <WiFi.h>           // deklarasi untuk memanggil librray wifi pada board esp32
#include "ThingsBoard.h"    // deklarasi library thingsboard yang dibuka dalam project

#define COUNT_OF(x) ((sizeof(x)/sizeof(0[x])) / ((size_t)(!(sizeof(x) % sizeof(0[x])))))

#define WIFI_AP_NAME              "Wokwi-GUEST" // ssid wifi yang digunakan
#define WIFI_PASSWORD             "" // passwrod wifi yang digunakan
#define THINGSBOARD_SERVER        "thingsboard.cloud" // alamat server thingsboard ayng digunakan
#define THINGSBOARD_ACCESSTOKEN   "XXqWoQE2waqq5mJLMjjs" // access token dari device thingsboard yang digunakan

WiFiClient espClient;
ThingsBoard tb(espClient);
int status = WL_IDLE_STATUS;

// deklarasi array untuk pin led yang dikontrol melalui thingsboard
uint8_t leds_control[] = { 14, 13, 12 };

DHTesp dht;
#define DHT_PIN 15

// Main application loop delay
int quant = 20;
// delay pengiriman data suhu/kelembaban
int send_delay = 2000;

// deklarasi variabel waktu yang dibutuhkan untuk mengirimkan data dht
int send_passed = 0;

// Set to true if application is subscribed for the RPC messages.
bool subscribed = false;
// LED number that is currenlty ON.
int current_led = 0;

float temperature = 0;
float humidity = 0;

RPC_Response processSetGpioState(const RPC_Data &data) //perintah untuk menyalakan atau mematikan (perintah kontrol) outputnya
{
  Serial.println("Received the set GPIO RPC method");

  int pin = data["pin"];
  bool enabled = data["enabled"];

  if (pin < COUNT_OF(leds_control)) {
    Serial.print("Setting LED ");
    Serial.print(pin);
    Serial.print(" to state ");
    Serial.println(enabled);

    digitalWrite(leds_control[pin], enabled);
  }

  return String("{\"" + String(pin) + "\": " + String(enabled?"true":"false") + "}");
}

RPC_Response processGetGpioState(const RPC_Data &data) //membaca kondisi dari gpio
{
  Serial.println("Received the get GPIO RPC method");
  String respStr = "{";
  
  for (size_t i = 0; i < COUNT_OF(leds_control); ++i) {
    int pin = leds_control[i];
    Serial.print("Getting LED ");
    Serial.print(pin);
    Serial.print(" state ");
    bool ledState = digitalRead(pin);
    Serial.println(ledState);

    respStr += String("\"" + String(i) + "\": " + String(ledState?"true":"false") + ", ");
  }  
  respStr = respStr.substring(0, respStr.length() - 2);
  respStr += "}";
  return respStr;
}

// konversi perintah menjadi perintah yang dikenal oleh rpc
RPC_Callback callbacks[] = {
  { "setGpioStatus",    processSetGpioState },
  { "getGpioStatus",    processGetGpioState },
};

void setup() {
  Serial.begin(115200);
  InitWiFi();

  // Inisialiasi pinmode
  for (size_t i = 0; i < COUNT_OF(leds_control); ++i) {
    pinMode(leds_control[i], OUTPUT);
  }

  // inisiailisasi dari sensor dht
  dht.setup(DHT_PIN, DHTesp::DHT22);

}

void loop() 
{
  delay(quant);

  send_passed += quant;

  // perintah koneksi ulang apabila terputus
  if (WiFi.status() != WL_CONNECTED) {
    reconnect();
    return;
  }

  // perintah rekoneksi dengan thingsboard
  if (!tb.connected()) {
    subscribed = false;

    // Connect to the ThingsBoard
    Serial.print("Connecting to: ");
    Serial.print(THINGSBOARD_SERVER);
    Serial.print(" with token ");
    Serial.println(THINGSBOARD_ACCESSTOKEN);
    if (!tb.connect(THINGSBOARD_SERVER, THINGSBOARD_ACCESSTOKEN)) {
      Serial.println("Failed to connect");
      return;
    }
  }

  // perintah menghubungkan dengan rpc
  if (!subscribed) {
    Serial.println("Subscribing for RPC... ");

    // Perform a subscription. All consequent data processing will happen in
    // callbacks as denoted by callbacks[] array.
    if (!tb.RPC_Subscribe(callbacks, COUNT_OF(callbacks))) {
      Serial.println("Failed to subscribe for RPC");
      return;
    }

    Serial.println("Subscribe done");
    subscribed = true;
  }  

  // Check if it is a time to send DHT22 temperature and humidity
  if (send_passed > send_delay) {
    Serial.println();
    Serial.print("Sending data... ");
    TempAndHumidity lastValues = dht.getTempAndHumidity();    

    if (isnan(lastValues.humidity) || isnan(lastValues.temperature)) {
      Serial.println("Failed to read from DHT sensor!");
    } else {
      temperature = lastValues.temperature;
      Serial.print("temperature: ");
      Serial.print(temperature);
      humidity = lastValues.humidity;
      Serial.print(" humidity: ");
      Serial.print(humidity);
      tb.sendTelemetryFloat("suhu", temperature);
      tb.sendTelemetryFloat("kelembaban", humidity);
    }
    send_passed = 0;
  }
  tb.loop(); //perintah ekseskuasi thingsboard
}

void InitWiFi() //perintah koneksi ke wifi
{
  Serial.println("Connecting to AP ...");
  // attempt to connect to WiFi network

  WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected to AP");
}

void reconnect() { //perintah recconect atau koneksi ulang
  // Loop until we're reconnected
  status = WiFi.status();
  if ( status != WL_CONNECTED) {
    WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
    }
    Serial.println("Connected to AP");
  }
}