#include <WiFi.h>
#include "ThingsBoard.h"
#include <ESP32Servo.h>
#include "RTClib.h"
Servo myservo;
RTC_DS3231 rtc;
char daysOfTheWeek[7][12] = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"};

#define CURRENT_FIRMWARE_TITLE    "TEST"
#define CURRENT_FIRMWARE_VERSION  "1.0.0"
#define WIFI_SSID           "Wokwi-GUEST"
#define WIFI_PASSWORD       ""
#define TOKEN               "gFfGOdVFvIWp7hL8Rhku"
#define THINGSBOARD_SERVER  "thingsboard.cloud"
#define Echo 12
#define Trig 13
#define Led 14
float jarak = 0;
float kapasitas_pakan = 0;

WiFiClient espClient;
ThingsBoard tb(espClient);
int status = WL_IDLE_STATUS;

void InitWiFi()
{
  Serial.println("Connecting to AP ...");
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected to AP");
}

void reconnect() {
  status = WiFi.status();
  if ( status != WL_CONNECTED) {
    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
    }
    Serial.println("Connected to AP");
  }
}

void baca_jarak()
{
  digitalWrite(Trig, LOW);
  delayMicroseconds(2);
  digitalWrite(Trig, HIGH);
  delayMicroseconds(10);
  digitalWrite(Trig, LOW);
  int duration = pulseIn(Echo, HIGH);
  jarak = duration * 0.034 / 2;
  //tinggi tabung pakan = 30cm, 1cm mewakili 1 liter
  //pemasangan sensor ultrasonic di titik 40cm
  kapasitas_pakan = 40 - jarak; //jarak= 10-40cm
}

void setup() {
  Serial.begin(115200);
  Serial.println();
  InitWiFi();
  if (! rtc.begin()) {
    Serial.println("Couldn't find RTC");
    Serial.flush();
    abort();
  }
  pinMode(Trig, OUTPUT);
  pinMode(Echo, INPUT);
  pinMode(Led, OUTPUT);
  myservo.attach(5);
}

void loop() {  
  if (WiFi.status() != WL_CONNECTED) {
    reconnect();
  }

  if (!tb.connected()) {
    // Connect to the ThingsBoard
    Serial.print("Connecting to: ");
    Serial.print(THINGSBOARD_SERVER);
    Serial.print(" with token ");
    Serial.println(TOKEN);
    if (!tb.connect(THINGSBOARD_SERVER, TOKEN)) {
      Serial.println("Failed to connect");
      return;
    }
  }

  //view time
  DateTime now = rtc.now(); 
  Serial.print("Current time: ");
  Serial.print(now.year(), DEC);
  Serial.print('/');
  Serial.print(now.month(), DEC);
  Serial.print('/');
  Serial.print(now.day(), DEC);
  Serial.print(" (");
  Serial.print(daysOfTheWeek[now.dayOfTheWeek()]);
  Serial.print(") ");
  Serial.print(now.hour(), DEC);
  Serial.print(':');
  Serial.print(now.minute(), DEC);
  Serial.print(':');
  Serial.print(now.second(), DEC);
  Serial.println();        

  //servo motor control and led indicator
  if(now.hour() == 9 && now.minute() == 41)  {    
    myservo.write(90);  
    digitalWrite(Led, HIGH);          
  }
  else if (now.hour() == 17 && now.minute() == 00){
    myservo.write(90); 
    digitalWrite(Led, HIGH);  
  }
  else if (now.hour() == 22 && now.minute() == 00){
    myservo.write(90); 
    digitalWrite(Led, HIGH);  
  }
  else{
    myservo.write(0); 
    digitalWrite(Led, LOW);  
    delay(1000);
  } 
  
  //feeder monitor capacity
  baca_jarak();
  tb.sendTelemetryFloat("Kapasitas Pakan", kapasitas_pakan);

  //read led indicator
  int led_status = digitalRead(Led);
  tb.sendTelemetryInt("Operasi Pemberi Pakan", led_status);

  //read location
  tb.sendTelemetryFloat("lat", -8.1457606);
  tb.sendTelemetryFloat("long", 112.4522431);

  Serial.print("Kapasitas Pakan: ");
  Serial.print(kapasitas_pakan);
  Serial.println(" liter");  
  tb.loop();  
}