#include <DHTesp.h>         // DHT for ESP32 library
#include <WiFi.h>           // WiFi control for ESP32
//#include <ThingsBoard.h>    // ThingsBoard SDK
#include "ThingsBoard.h"

#define COUNT_OF(x) ((sizeof(x)/sizeof(0[x])) / ((size_t)(!(sizeof(x) % sizeof(0[x])))))

#define WIFI_AP_NAME              "Wokwi-GUEST"
#define WIFI_PASSWORD             ""
#define THINGSBOARD_SERVER        "thingsboard.cloud"
#define THINGSBOARD_ACCESSTOKEN   "AoosX9xRSwfH92iFtNWO"

#define SERIAL_DEBUG_BAUD    115200

WiFiClient espClient;
ThingsBoard tb(espClient);
int status = WL_IDLE_STATUS;

// Array with LEDs that should be lit up one by one
uint8_t leds_cycling[] = { 21, 19, 18 };

// Array with LEDs that should be controlled from ThingsBoard, one by one
uint8_t leds_control[] = { 26, 33, 25 }; // led {merah (panas) > 34, 34 >= hijau (normal) =< 26, biru (dingin) < 26}

DHTesp dht;
#define DHT_PIN 14

//define relay pin
#define relaypin1 21 // sirkuit pendingin (Relay Kanan)
#define relaypin2 22 // sirkuit pemanas (Relay Kiri)

//define tone buzzer
#define toneBuzzer 5

// Main application loop delay
int quant = 20;
// Initial period of LED cycling.
int led_delay = 1000;
// Period of sending a temperature/humidity data.
int send_delay = 2000;

// Time passed after LED was turned ON, milliseconds.
int led_passed = 0;
// Time passed after temperature/humidity data was sent, milliseconds.
int send_passed = 0;

// Set to true if application is subscribed for the RPC messages.
bool subscribed = false;
// LED number that is currenlty ON.
int current_led = 0;

float temperature = 0;
float humidity = 0;

RPC_Response processDelayChange(const RPC_Data &data)
{
  Serial.println("Received the set delay RPC method");

  // Process data

  led_delay = data;

  Serial.print("Set new delay: ");
  Serial.println(led_delay);

  return String(led_delay);
}

RPC_Response processGetDelay(const RPC_Data &data)
{
  Serial.println("Received the get value method");
  return String(led_delay);
}

RPC_Response processSetGpioState(const RPC_Data &data)
{
  Serial.println("Received the set GPIO RPC method");

  int pin = data["pin"];
  bool enabled = data["enabled"];

  if (pin < COUNT_OF(leds_control)) {
    Serial.print("Setting LED ");
    Serial.print(pin);
    Serial.print(" to state ");
    Serial.println(enabled);

    digitalWrite(leds_control[pin], enabled);
  }

  return String("{\"" + String(pin) + "\": " + String(enabled?"true":"false") + "}");
}

RPC_Response processGetGpioState(const RPC_Data &data)
{
  Serial.println("Received the get GPIO RPC method");
  String respStr = "{";
  
  for (size_t i = 0; i < COUNT_OF(leds_control); ++i) {
    int pin = leds_control[i];
    Serial.print("Getting LED ");
    Serial.print(pin);
    Serial.print(" state ");
    bool ledState = digitalRead(pin);
    Serial.println(ledState);

    respStr += String("\"" + String(i) + "\": " + String(ledState?"true":"false") + ", ");
  }  
  respStr = respStr.substring(0, respStr.length() - 2);
  respStr += "}";
  return respStr;
}


// RPC handlers
RPC_Callback callbacks[] = {
  { "setValue",         processDelayChange },
  { "getValue",         processGetDelay },  
  { "setGpioStatus",    processSetGpioState },
  { "getGpioStatus",    processGetGpioState },
};

void setup() {
  Serial.begin(SERIAL_DEBUG_BAUD);
  WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
  InitWiFi();

  // Pinconfig
  for (size_t i = 0; i < COUNT_OF(leds_cycling); ++i) {
    pinMode(leds_cycling[i], OUTPUT);
  }

  for (size_t i = 0; i < COUNT_OF(leds_control); ++i) {
    pinMode(leds_control[i], OUTPUT);
  }

  // Initialize temperature sensor
  dht.setup(DHT_PIN, DHTesp::DHT22);

  //Initialize Relay pinMode
  pinMode(relaypin1, OUTPUT);
  pinMode(relaypin2, OUTPUT);

  //Initialize Buzzer pinMode
  pinMode(toneBuzzer, OUTPUT);

}

void loop() 
{
  delay(quant);

  led_passed += quant;
  send_passed += quant;

  // Check if next LED should be lit up
  if (led_passed > led_delay) {
    // Turn off current LED
    digitalWrite(leds_cycling[current_led], LOW);
    led_passed = 0;
    current_led = current_led >= 2 ? 0 : (current_led + 1);
    // Turn on next LED in a row
    digitalWrite(leds_cycling[current_led], HIGH);
  }

  // Reconnect to WiFi, if needed
  if (WiFi.status() != WL_CONNECTED) {
    reconnect();
    return;
  }

  // Reconnect to ThingsBoard, if needed
  if (!tb.connected()) {
    subscribed = false;

    // Connect to the ThingsBoard
    Serial.print("Connecting to: ");
    Serial.print(THINGSBOARD_SERVER);
    Serial.print(" with token ");
    Serial.println(THINGSBOARD_ACCESSTOKEN);
    if (!tb.connect(THINGSBOARD_SERVER, THINGSBOARD_ACCESSTOKEN)) {
      Serial.println("Failed to connect");
      return;
    }
  }

  // Subscribe for RPC, if needed
  if (!subscribed) {
    Serial.println("Subscribing for RPC... ");

    // Perform a subscription. All consequent data processing will happen in
    // callbacks as denoted by callbacks[] array.
    if (!tb.RPC_Subscribe(callbacks, COUNT_OF(callbacks))) {
      Serial.println("Failed to subscribe for RPC");
      return;
    }

    Serial.println("Subscribe done");
    subscribed = true;
  }  

  // Check if it is a time to send DHT22 temperature and humidity
  if (send_passed > send_delay) {
    Serial.println();
    Serial.print("Sending data... ");
    TempAndHumidity lastValues = dht.getTempAndHumidity();    

    if (isnan(lastValues.humidity) || isnan(lastValues.temperature)) {
      Serial.println("Failed to read from DHT sensor!");
    } else {
      temperature = lastValues.temperature;
      Serial.print("temperature: ");
      Serial.print(temperature);
      //humidity = lastValues.humidity;
      //Serial.print(" humidity: ");
      //Serial.print(humidity);
      tb.sendTelemetryFloat("temperature", temperature);
      //tb.sendTelemetryFloat("humidity", humidity);
    }
    send_passed = 0;
  }

  if (temperature > 34){
    digitalWrite(leds_control[0], HIGH);
    digitalWrite(leds_control[1], LOW);
    digitalWrite(leds_control[2], LOW);

    tone(toneBuzzer, 500, 10);

    digitalWrite(relaypin1, HIGH); // sirkuit pendingin menyambung (NO->NC) -> membuka keran pendingin
    digitalWrite(relaypin2, LOW); // sirkuit pemanas tidak menyambung (NO) -> keran pemanas tidak terbuka
  }
  if (temperature <= 34 && temperature >=26 ){
    digitalWrite(leds_control[0], LOW);
    digitalWrite(leds_control[1], HIGH);
    digitalWrite(leds_control[2], LOW);

    digitalWrite(relaypin1, LOW);  // sirkuit pendingin tidak menyambung (NO) -> keran pendingin tidak terbuka
    digitalWrite(relaypin2, LOW); // sirkuit pemanas tidak menyambung (NO) -> keran pemanas tidak terbuka
  }
  else if (temperature < 26){
    digitalWrite(leds_control[0], LOW);
    digitalWrite(leds_control[1], LOW);
    digitalWrite(leds_control[2], HIGH);

    digitalWrite(relaypin1, LOW);  // sirkuit pendingin tidak menyambung (NO) -> keran pendingin tidak terbuka
    digitalWrite(relaypin2, HIGH); // sirkuit pemanas menyambung (NO->NC) -> membuka keran pemanas
  }
  tb.loop();
}

void InitWiFi()
{
  Serial.println("Connecting to AP ...");
  // attempt to connect to WiFi network

  WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected to AP");
}

void reconnect() {
  // Loop until we're reconnected
  status = WiFi.status();
  if ( status != WL_CONNECTED) {
    WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
    }
    Serial.println("Connected to AP");
  }
}