#include <EButton.h>
#include <LiquidCrystal_I2C.h>

EButton button(2);
LiquidCrystal_I2C lcd(0x27, 20, 4);
unsigned long start;
unsigned long elapsed;
unsigned long history[3];
bool oddClick = true;


uint8_t extract(unsigned long& time, uint8_t const part) {
  uint8_t result = time % part;
  time /= part;
  return result;
}

void format(char buffer[], unsigned long const time) {
  if (not time) {
    buffer[0] = 0;
    return;
  }
  
  unsigned long time_ = time / 100;
  uint8_t tenths = extract(time_, 10);
  uint8_t seconds = extract(time_, 60);
  uint8_t minutes = extract(time_, 60);
  uint8_t hours = extract(time_, 60);
  sprintf(buffer, "%02i:%02i:%02i:%i", hours, minutes, seconds, tenths);
}

void click(EButton&) {
  static size_t index = 0;

  oddClick = not oddClick;
  if (oddClick) {
    return;
  }

  history[index] = elapsed;
  index = (index + 1) % 3;
  start = millis();

  for (size_t i = 0; i < 3; i++) {
    char buffer[11];
    format(buffer, history[(index + 2 - i) % 3]);
    lcd.setCursor(0, i + 1);
    lcd.print(buffer);
  }
}


void setup() {
  Serial.begin(9600);

  lcd.init();
  lcd.backlight();

  button.attachSingleClick(click);
}

void loop() {
  if (not oddClick) {
    elapsed = millis() - start;
  
    char buffer[11];
    format(buffer, elapsed);
    lcd.setCursor(0, 0);
    lcd.print(buffer);
  }
  button.tick();
}