//pin
#define LED 21
#define LDR 34
#define RELAY_FAN 19
#define DHT_PIN 15

#define GAMMA 0.7
#define RL10 50


#include <WiFi.h>
#include <WiFiClient.h>
#include "DHTesp.h"
#include <PubSubClient.h>
DHTesp dhtSensor;

char ssid[] = "Wokwi-GUEST";
char pass[] = "";
const char* mqtt_server = "test.mosquitto.org";

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE  (50)
char msg[MSG_BUFFER_SIZE];

void sendData(float temperature, float humidity, float lux, bool fanStatus, bool lampStatus){
  client.publish("/indobot/mqtt/IOT4-15/dede-kurniawan/smart-farm/1/temperature", String(temperature, 2).c_str());
  client.publish("/indobot/mqtt/IOT4-15/dede-kurniawan/smart-farm/1/humidity", String(humidity,1).c_str());
  client.publish("/indobot/mqtt/IOT4-15/dede-kurniawan/smart-farm/1/lux", String(lux, 0).c_str());
  client.publish("/indobot/mqtt/IOT4-15/dede-kurniawan/smart-farm/1/fanStatus", String(fanStatus).c_str());
  client.publish("/indobot/mqtt/IOT4-15/dede-kurniawan/smart-farm/1/lampStatus", String(lampStatus).c_str());
}

void sendSensor(){
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();

  int analogValue = analogRead(LDR);
  float voltage = analogValue /4095.0;
  float resistance = 10000 * voltage / (1 - voltage);
  float lux = pow(RL10 * 1e3 * pow(10, GAMMA) / resistance, (1 / GAMMA));
  bool fanStatus = false;
  bool lampStatus = false;
  
  if(data.temperature > 45){
    fanStatus = true;
  } 
  digitalWrite(RELAY_FAN, fanStatus);

  if (lux <= 50){
    lampStatus = true;
  }
  digitalWrite(LED, lampStatus);


  sendData(data.temperature, data.humidity, lux, fanStatus, lampStatus);
}


void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, pass);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}


void reconnect() {
  // Loop until we're reconnected
  do {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(1000);
    }
  }while (!client.connected());
}

void setup()
{
  Serial.begin(9600);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  pinMode(LED, OUTPUT);
  pinMode(RELAY_FAN, OUTPUT);

  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);
}

void loop()
{
  if (!client.connected()) {
    Serial.println("MQTT is not connected");
    reconnect();
  }
  sendSensor();
  delay(500);

  client.loop();
}