#include <WiFi.h>
#include "ThingsBoard.h"

#define ECHO_PIN  19
#define TRIG_PIN  18
#define RELAY_PIN 15
#define LEDRED_PIN 5
#define LEDYEL_PIN 4
#define LEDGRN_PIN 2

#define CURRENT_FIRMWARE_TITLE    "TEST"
#define CURRENT_FIRMWARE_VERSION  "1.0.0"

#define TOKEN               "KJHKob4BNHTpUfFVrgNR" //sesuaikan token dengan thingsboard yg dipake
#define THINGSBOARD_SERVER  "thingsboard.cloud"

#define WIFI_SSID           "Wokwi-GUEST"
#define WIFI_PASSWORD       ""

// Initialize ThingsBoard client
WiFiClient espClient;
// Initialize ThingsBoard instance
ThingsBoard tb(espClient);
// the Wifi radio's status
int status = WL_IDLE_STATUS;

unsigned long interval          = 1000;    // interval update data (1 detik)
unsigned long previousMillis    = 0;       // millis() returns an unsigned long.
float distance;

int penuh                       = 22;
int kosong                      = 150;
int batas_atas_penuh            = 22;
int batas_bawah_penuh           = 61;
int batas_bawah_setengah        = 111;
int batas_bawah_kosong          = 150;
int pompa_state                 = 0;

void setup() {
  Serial.begin(115200);

  //menyambung ke wifi
  status = WiFi.status();
  if ( status != WL_CONNECTED) {
    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
    }
    Serial.println("");
    Serial.println("Connected to AP");
  }

  if (!tb.connected()) { // koneksi ke thingsboard
    Serial.print("Connecting to: ");
    Serial.print(THINGSBOARD_SERVER);
    Serial.print(" with token ");
    Serial.println(TOKEN);
    if (!tb.connect(THINGSBOARD_SERVER, TOKEN)) {
      Serial.println("Failed to connect");
      return;
    }
  }

  pinMode(RELAY_PIN, OUTPUT);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(LEDRED_PIN, OUTPUT);
  pinMode(LEDYEL_PIN, OUTPUT);
  pinMode(LEDGRN_PIN, OUTPUT);

}

float readDistanceCM() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  int duration = pulseIn(ECHO_PIN, HIGH);
  return duration * 0.034 / 2;
}

void loop() {
   
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {

    distance = readDistanceCM();
    Serial.print("Measured distance: ");
    Serial.println(readDistanceCM());

    tb.sendTelemetryFloat("KETINGGIAN_AIR", distance);
    previousMillis = millis();
  }
  
  //menutup valve jika penuh
  if(pompa_state == 1){
    if(distance <= penuh){
      digitalWrite(RELAY_PIN, LOW);
      pompa_state = 0;
    }
  }
  
  //membuka valve ketika air kosong
  if(pompa_state == 0){
    if(distance >= kosong){
      digitalWrite(RELAY_PIN, HIGH);
      pompa_state = 1;
    }
  }

  //indikator led merah
  if(distance > batas_bawah_setengah){
    digitalWrite(LEDGRN_PIN, LOW);
    digitalWrite(LEDRED_PIN, HIGH);
    digitalWrite(LEDYEL_PIN, LOW);
  }

  //indikator led kuning
  if(distance < batas_bawah_setengah && distance > batas_bawah_penuh){
    digitalWrite(LEDGRN_PIN, LOW);
    digitalWrite(LEDRED_PIN, LOW);
    digitalWrite(LEDYEL_PIN, HIGH);
  }

  //indikator led hijau
  if(distance <= batas_bawah_penuh){
    digitalWrite(LEDGRN_PIN, HIGH);
    digitalWrite(LEDRED_PIN, LOW);
    digitalWrite(LEDYEL_PIN, LOW);
    
  }

  

  
}