Wokwi - Online ESP32, STM32, Arduino Simulator

#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <uri/UriBraces.h>

#define WIFI_SSID "Wokwi-GUEST"
#define WIFI_PASSWORD ""
#define WIFI_CHANNEL 6

WebServer server(80);

const int Green = 26;
const int Red = 27;

bool GreenState = false;
bool RedState = false;

void sendHtml() {
  String response = R"(
    <!DOCTYPE html><html>
      <head>
        <title>Train Traffic Light Control</title>
        <meta name="viewport" content="width=device-width, initial-scale=1">
        <style>
          html { font-family: sans-serif; text-align: center; }
          body { display: inline-flex; flex-direction: column; }
          h1 { margin-bottom: 1.2em; } 
          h2 { margin: 0; }
          div { display: grid; grid-template-columns: 1fr 1fr; grid-template-rows: auto auto; grid-auto-flow: column; grid-gap: 1em; }
          .btn { background-color: #5B5; border: none; color: #fff; padding: 0.5em 1em;
                 font-size: 2em; text-decoration: none }
          .btn.OFF { background-color: #333; }
        </style>
      </head>
            
      <body>
        <h1>Train Traffic Light Control</h1>

        <div>
          <h2>Green</h2>
          <a href="/toggle/1" class="btn Green_TEXT">Green_TEXT</a>
          <h2>Red</h2>
          <a href="/toggle/2" class="btn Red_TEXT">Red_TEXT</a>
        </div>
      </body>
    </html>
  )";
  response.replace("Green_TEXT", GreenState ? "ON" : "OFF");
  response.replace("Red_TEXT", RedState ? "ON" : "OFF");
  server.send(200, "text/html", response);
}

void setup(void) {
  Serial.begin(115200);
  pinMode(Green, OUTPUT);
  pinMode(Red, OUTPUT);

  WiFi.begin(WIFI_SSID, WIFI_PASSWORD, WIFI_CHANNEL);
  Serial.print("Connecting to WiFi ");
  Serial.print(WIFI_SSID);
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.println(" Connected!");

  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  server.on("/", sendHtml);

  server.on(UriBraces("/toggle/{}"), []() {
    String led = server.pathArg(0);
    Serial.print("Toggle LED #");
    Serial.println(led);

    switch (led.toInt()) {
      case 1:
        GreenState = !GreenState;
        digitalWrite(Green, GreenState);
        break;
      case 2:
        RedState = !RedState;
        digitalWrite(Red, RedState);
        break;
    }

    sendHtml();
  });

  server.begin();
  Serial.println("Train Traffic Light Control server started");
}

void loop(void) {
  server.handleClient();
  delay(2);
}