#include <WiFi.h>
#include "PubSubClient.h"
#include "DHT.h"
#include <HTTPClient.h>

const char * MQTTServer = "broker.emqx.io";
const char * MQTT_Topic = "SmartHome/Led";
const char * MQTT_Topic1 = "SmartHome/nhietdo";
const char * MQTT_Topic2 = "SmartHome/doam";
const char * MQTT_Topic3 = "SmartHome/chuyendong";
const char * MQTT_ID = "SmartHome-vlute-iot";
int Port = 1883;

HTTPClient http;
#define DHTPIN 15
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

WiFiClient espClient;
PubSubClient client(espClient);
const int ledPK = 2;
const int ledPN = 4;
const int ledNB = 5;
int pir = 14;
int pirState = LOW;  
int val = 0;
int buzzer = 21;

void WIFIConnect() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", "");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected");
  Serial.print(", IP address: ");
  Serial.println(WiFi.localIP());
}

void MQTT_Reconnect() {
  while (!client.connected()) {
    if (client.connect("VLUTE-IoT")) {
      Serial.print("MQTT Topic: ");
      Serial.print(MQTT_Topic);
      Serial.print(" connected");
      client.subscribe(MQTT_Topic);
      Serial.println("");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  String stMessage;

  for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    stMessage += (char)message[i];
  }
  //đèn phòng khách
  if (stMessage == "Bật đèn phòng khách") {
    digitalWrite(ledPK, HIGH);
  }
  else if (stMessage == "Tắt đèn phòng khách") {
    digitalWrite(ledPK, LOW);
  }
  //đèn phòng ngủ
  if (stMessage == "Bật đèn phòng ngủ") {
    digitalWrite(ledPN, HIGH);
  }
  else if (stMessage == "Tắt đèn phòng ngủ") {
    digitalWrite(ledPN, LOW);
  }
  //đèn nhà bếp
  if (stMessage == "Bật đèn nhà bếp") {
    digitalWrite(ledNB, HIGH);
  }
  else if (stMessage == "Tắt đèn nhà bếp") {
    digitalWrite(ledNB, LOW);
  }
  Serial.println();
}

void setup() {
  Serial.begin(115200);
  dht.begin();
  pinMode(buzzer, OUTPUT);
  pinMode(pir, INPUT);
  WIFIConnect();
  client.setServer(MQTTServer, Port);
  client.setCallback(callback);
  pinMode(ledNB, OUTPUT);
  pinMode(ledPN, OUTPUT);
  pinMode(ledPK, OUTPUT);
}

void loop() {
  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();

  float h = dht.readHumidity();
  float t = dht.readTemperature();
  Serial.print("Humidity: ");
  Serial.print(h);
  Serial.print("%  Temperature: ");
  Serial.print(t);
  Serial.println("-----");
  client.publish("SmartHome/nhietdo",String(t).c_str());
  client.publish("SmartHome/doam",String(h).c_str());

  val = digitalRead(pir);
  if (val == HIGH) {
    digitalWrite(buzzer, HIGH);
    if (pirState == LOW) {
      Serial.println("Đã phát hiện chuyển động!");
      pirState = HIGH;
    }
  } else {
    digitalWrite(buzzer, LOW);
    if (pirState == HIGH) {
      Serial.println("Không phát hiện chuyển động.");
      pirState = LOW;
    }
  }

  if(pirState == HIGH){
    client.publish("SmartHome/chuyendong","Đã phát hiện chuyển động!");
  }else{
    client.publish("SmartHome/chuyendong","Không phát hiện chuyển động!");
  }

  delay(1000);
}