#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHTesp.h>
//bibliotheken für Netzwerk / Broker
#include <PubSubClient.h>
#include <WiFi.h>

const int DHT_PIN = 15;

DHTesp dhtSensor;

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

#define LED_red 25
#define LED_blue 26
#define LED_green 27

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

//Network setup
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;

void setup_wifi() {

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  Serial.println("WIFI connected");
}

void reconnect() {
  while(!client.connected()){
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())){
      Serial.println("connected");

      client.publish("/FI21-2-Johannes", "Connection successfull");
      client.subscribe("/FI21-2-Johannes");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }

  }
}

void callback(char* topic, byte* payload, unsigned int length) { //perintah untuk menampilkan data ketika esp32 di setting sebagai subscriber
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) { //mengecek jumlah data yang ada di topik mqtt
    Serial.print((char)payload[i]);
  }
  Serial.println();

  // Switch on the LED if an 1 was received as first character
  if ((char)payload[0] == '1') {
    digitalWrite(2, LOW);   // Turn the LED on (Note that LOW is the voltage level
    // but actually the LED is on; this is because
    // it is active low on the ESP-01)
  } else {
    digitalWrite(2, HIGH);  // Turn the LED off by making the voltage HIGH
  }
}

void setup() {
  Serial.begin(115200);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3D for 128x64
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

  delay(500);
  display.clearDisplay();

  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 10);
  display.display();

  pinMode(LED_red, OUTPUT);
  pinMode(LED_blue, OUTPUT);
  pinMode(LED_green, OUTPUT);

  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
  /* Serial.println("Temp: " + String(data.temperature, 2) + "°C");
  Serial.println("Humidity: " + String(data.humidity, 1) + "%");
  Serial.println("---"); */
  display.clearDisplay();
  display.setCursor(0, 10);
  display.println("Temp: " + String(data.temperature, 2) + "°C");
  display.println("Humidity: " + String(data.humidity, 1) + "%");
  display.display();

  digitalWrite(LED_red, LOW);
  digitalWrite(LED_blue, LOW);
  digitalWrite(LED_green, LOW);

  if(data.temperature > 22){
    //LED rot
    digitalWrite(LED_red, HIGH);
  } else if(data.temperature < 18){
    //LED blau
    digitalWrite(LED_blue, HIGH);
  }

  if(data.humidity < 40 || data.humidity > 50){
    //LED grün
    digitalWrite(LED_green, HIGH);
  }

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;

    String temp = String(data.temperature, 2) + "°C";
    client.publish("/FI21-2-Johannes", temp.c_str());
  }

  delay(5000);
}