/*Alla pressione del pulsante si attiva o disattiva il lampeggo di un led*/
int led = 13;
byte pulsante =12;
byte stato= LOW;  // variabile globale che memorizza lo stato del pulsante
volatile unsigned long previousMillis = 0;
volatile unsigned short numberOfButtonInterrupts = 0;
volatile bool pressed;
#define DEBOUNCETIME 50
 
void setup() {
  Serial.begin(115200);
  pinMode(led, OUTPUT);
  pinMode(pulsante, INPUT);
  attachInterrupt(digitalPinToInterrupt(pulsante), switchPressed, CHANGE );  
  pressed = false;
}

// Interrupt Service Routine (ISR)
void switchPressed ()
{
  byte val = digitalRead(pulsante);
  if(val == HIGH){
    if(!pressed){ // intervento immediato sul fronte di salita
        pressed = true;
        stato = !stato; // logica da attivare sul fronte (toggle)
    }
    numberOfButtonInterrupts++; // contatore rimbalzi
    previousMillis = millis(); // tempo evento
  }
}  // end of switchPressed

void waitUntilInputChange()
{
    // sezione critica
    // protegge previousMillis che, essendo a 16it, potrebbe essere danneggiata se interrotta da un interrupt
    // numberOfButtonInterrupts è 8bit e non è danneggiabile ne in lettura ne in scrittura
    noInterrupts();
    // il valore lastintTime potrà essere in seguito letto interrotto ma non danneggiato
    unsigned long lastintTime = previousMillis;
    interrupts();

    if ((numberOfButtonInterrupts != 0) //flag interrupt! Rimbalzo o valore sicuro? 
        && (millis() - lastintTime > DEBOUNCETIME )//se è passato il transitorio 
        && digitalRead(pulsante) == LOW)//se è sul fronte di discesa
    { 
        Serial.print("HIT: "); Serial.print(numberOfButtonInterrupts);
        pressed = false;
        numberOfButtonInterrupts = 0; // reset del flag (riarmo pulsante differito sul fronte di discesa)
        Serial.println(" in DISCESA debounced");            
    }
}
// loop principale
void loop() {
	waitUntilInputChange();
	if (stato) {
		digitalWrite(led, !digitalRead(led));   	// inverti lo stato precedente del led
		delay(1000);
	} else {
		digitalWrite(led, LOW);    	// turn the LED off by making the voltage LOW
    delay(10);
	}
}