/**
   ESP32 + DHT22 Example for Wokwi
   
   https://wokwi.com/arduino/projects/322410731508073042
*/

#include "DHTesp.h"
#include <DallasTemperature.h>
#include <LiquidCrystal_I2C.h>
#include <WiFi.h>
#include <OneWire.h>
#include "ThingSpeak.h"

#define DHT_PIN 15
#define DALLAS_TEMP_PIN 4
#define SOIL_MOISTURE_PIN 5
#define PUSH_BUTTON 2

OneWire oneWire(DALLAS_TEMP_PIN);      // Setup a oneWire instance to communicate with dallas temperature sensor

DallasTemperature dallasTemp(&oneWire);

LiquidCrystal_I2C LCD = LiquidCrystal_I2C(0x27, 16, 2);  // Set up I2C LCD

DHTesp dhtSensor;    // set up DHT22 sensor

WiFiClient client;

// Sensor reading variables
float dht_temp;
float dht_humidity;
float soil_temp;

//ThingSpeak channelID and Write API key
unsigned long myChannelNumber = 1970065;  
const char * myWriteAPIKey = "UN6WD7YI86VG8PBY";

//Time variables
unsigned long cloud_lastTime = 0;
unsigned long cloudDelay = 15000;      //seconds intervals to update ThingSpeak cloud

unsigned long screen_lastTime = 0;
unsigned long screenDelay = 2000;    //seconds intervals to update the serial monitor and LCD

int LCD_view = 0;           // a variable to switch what's being displayed on the LCD
bool cloudUpdate = false;       // A flag to track if the last cloud update was successful 

//WiFi Credentials
// const char* ssid = "Redmi Note 9S";   // your network SSID (name) 
// const char* password = "yinkus4ever";   // your network password


void setup() {
  Serial.begin(115200);

  pinMode(PUSH_BUTTON, INPUT_PULLUP);

  LCD.init();
  LCD.backlight();

  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  dallasTemp.begin();       // Start the DS18B20 sensor

  // WiFi.begin(ssid, password);
  WiFi.begin("Wokwi-GUEST", "", 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(250);
    Serial.print(".");
  }

 Serial.println("");
 Serial.println("WiFi connected");
 Serial.println("IP address: ");
 Serial.println(WiFi.localIP());

 ThingSpeak.begin(client);  // Initialize ThingSpeak
}

void loop() {
  // Reading from DHT22 Sensor
  TempAndHumidity  dht = dhtSensor.getTempAndHumidity();
  dht_temp = dht.temperature;
  dht_humidity = dht.humidity;

  // Reading from Dallas Temperature sensor
   dallasTemp.requestTemperatures();
   soil_temp = dallasTemp.getTempCByIndex(0);

   // Update sensor readngs on displays every "screenDelay" seconds
  if ((millis() - screen_lastTime) >= screenDelay) {
      update_Display(LCD_view);
      screen_lastTime = millis();
    }

  // Also update Screen if button is pushed
  if (digitalRead(PUSH_BUTTON) == LOW) {
     LCD_view++;
      if (LCD_view > 2) {
         LCD_view = 0;
        }
     update_Display(LCD_view);
  }
    

   // Update Sensor readings on cloud every "cloudDelay" seconds
  if ((millis() - cloud_lastTime) >= cloudDelay) {
      update_ThingSpeak();
      cloud_lastTime = millis();
    }
}


void update_Display(int viewOption) {
  Serial.println("Temp: " + String(dht_temp, 2) + "°C");
  Serial.println("Humidity: " + String(dht_humidity, 1) + "%");
  Serial.println("---");

    //LCD screen zero
  switch (viewOption) {
     case 0: 
         LCD.clear();
         LCD.setCursor(0, 0);
         LCD.print("Temp: " + String(dht_temp, 2) + "C");
         LCD.setCursor(0, 1);
         LCD.print("Humidity: " + String(dht_humidity, 1) + "%");
      break;
  
      //LCD Screen one
      case 1:
         LCD.clear();
         LCD.setCursor(0, 0);
         LCD.print("Soil Temp: " + String(soil_temp, 2) + "C");
         LCD.setCursor(0, 1);
         LCD.print("Soil Moist: " + String(dht_humidity, 1) + "%");
      break;

      // LCD Screen three
      case 2:
         LCD.clear();
         LCD.setCursor(0, 0);
         LCD.print("Last CloudUpdate");
         LCD.setCursor(0, 1);
         if (cloudUpdate)
             LCD.print("Successful");
        else
             LCD.print("Failed !");
    break;
  }

}

void update_ThingSpeak() {
   // set the fields with the values on thingspeak

  ThingSpeak.setField(1, dht_humidity);
  ThingSpeak.setField(2, dht_temp);
  ThingSpeak.setField(3, soil_temp);
 // ThingSpeak.setField(4, number4);

  int x = ThingSpeak.writeFields(myChannelNumber, myWriteAPIKey);
  if(x == 200){
    Serial.println("Channel update successful.");
    cloudUpdate = true;
  }
  else{
    Serial.println("Problem updating channel. HTTP error code " + String(x));
    cloudUpdate = false;
    // Notify the Update error in LCD
    LCD.clear();
    LCD.setCursor(0, 0);
    LCD.print("Cloud Update");
    LCD.setCursor(0, 1);
    LCD.print("Error " + String(x));
    delay(1000);
    LCD.clear();
  }
}