/*
ME106
Final Project – Driver-side Door Keyless Entry Keypad Simulation
Yasar Iqbal
*/

// Include these libraries
#include <Keypad.h>                                  // Keypad library
#include <Servo.h>                                   // Servo library


// Keypad Stuff
#define ROW_NUM    4                                // Four row keypad
#define COLUMN_NUM 4                                // Four column keypad
#define SERVO_PIN  10                               // Servo motor is connected to pin 10

char keys[ROW_NUM][COLUMN_NUM] = {                  // Keypad configuration
  {'1', '2', '3', 'A'},
  {'4', '5', '6', 'B'},
  {'7', '8', '9', 'C'},
  {'*', '0', '#', 'D'}
};

byte pin_rows[ROW_NUM] = {9, 8, 7, 6};              // Connect to the row pinouts of the keypad
byte pin_column[COLUMN_NUM] = {5, 4, 3, 2};         // Connect to the column pinouts of the keypad
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );


// Factory password
const String factorypassword = "93913";                  // change your password here
String input_password;
unsigned long lastTime;


// LED stuff
int outPin = 11;                                    // LED is connected to pin 11


// Servo stuff
Servo servo;                                        // Create servo object to control a servo
int angle = 0;                                      // Set the initial angle of servo motor to 0 degrees



void setup() {
  Serial.begin(9600);
  input_password.reserve(32);                       // maximum password size is 32, change if needed
  servo.attach(SERVO_PIN);
  servo.write(10);                                  // rotate servo motor to 10 degrees
  lastTime = millis();
}


void loop() {
char key = keypad.getKey();

  if (key) {
    Serial.println(key);

    if (key == '*') {
      input_password = ""; // reset the input password
    } else if (key == '#') {
      if (input_password == factorypassword) {
        Serial.println("The password is correct, rotating Servo Motor to 90°");
        angle = 90;
        servo.write(angle);
        lastTime = millis();
      } else {
        Serial.println("The password is incorrect, try again");
      }

      input_password = ""; // reset the input password
    } else {
      input_password += key; // append new character to input password string
    }
  }

  if (angle == 90 && (millis() - lastTime) > 5000) { // 5 seconds
    angle = 10;
    servo.write(angle);
    Serial.println("Rotating Servo Motor to 0°");
    }
}