/*
  Представляю свой вариант пивоварни на ардуино. Данная пивоварня полностью автоматизирует
  процесс затирания. Доварить сусло можно либо на газу, либо в ручном режиме установив температуру
  100 градусов.
  Обзор здесь https://youtu.be/boA3yTKD0TY
  Код в данном проекте изменен тк даныый сайт не поддерживает датчик температуры DS18B20,
  соответсвенно в реальном проекте вместо DHT22 нужно подключать именно его, вместо светодиода
  тверодотельное реле(желательно с контролем нуля), через которое нужно запитать ТЭН.
  Нужно удалить или закоментировать все строки с коментарием "удалить" и раскоментировать
  все строки с коментарием "Раскоментировать" перед завливкой скетча в ардуино.
  Готовый скетч можно скачать здесь https://yadi.sk/d/0x9-EBWJJSCw3A

  Поддержать проект можно:
  1. По номеру телефона +7 (920) 029-5558 через СБП (ЮМани, Максим К)
  2. На кошелек ЮМани 410018618410083 
  3. По ссылке https://yoomoney.ru/to/410018618410083

  =================================================================================
  MIT License

  Copyright (c) 2023 Max

  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files (the "Software"), to deal
  in the Software without restriction, including without limitation the rights
  to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  copies of the Software, and to permit persons to whom the Software is
  furnished to do so, subject to the following conditions:

  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.

  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  SOFTWARE.
  ==================================================================================
*/
#include <dht.h>                  //Удалить
#include <math.h>                // математическая библиотека
#include <Wire.h>                //  Подключаем библиотеку для работы с шиной I2C
#include <EEPROM.h>              // Подключаем библиотеку для работы с EEPROM
#include <LiquidCrystal_I2C.h>   // Библиотека для работы с LCD
#include <microDS18B20.h>        //библиотека датчика температуры
#include <EncButton.h>           // Библиотека работы с кнопками (антидребезг)

#define heater_pin 9               //пин управление тэн
#define buzzer_pin 3               // Пин подключения пассивной пищалки
#define DHT22_PIN 10                // удалить
dht DHT;                            // Удалить

Button butt_DOWN(5);   //Описываем пины кнопок
Button butt_LEFT(6);
Button butt_RIGHT(7);
Button butt_UP(4);
Button butt_OK(8);

LiquidCrystal_I2C lcd(0x27, 20, 4); //Подключаем дисплей с адрсеом 0x27
//MicroDS18B20<10> ds;                //датчик температуры на 10 пин       Раскоментировать

uint8_t main_ptr = 1;           //Указатель главного меню
uint8_t program_ptr = 1;        //Указатель меню выбора и редактирования программ
bool end_loop;                  //Флаг выхода из меню выбора и редактирования программ
float cur_temp = 0;          //текущаяя температура

void setup() {
  pinMode(buzzer_pin, OUTPUT);
  pinMode(heater_pin, OUTPUT);  
  pinMode(11, OUTPUT); //временно для датчика температуры
  pinMode(12, OUTPUT); //временно для датчика температуры
  digitalWrite(11, HIGH); //временно для датчика температуры
  digitalWrite(12, LOW); //временно для датчика температуры
  lcd.init();       //  Инициируем работу с LCD дисплеем
  lcd.backlight();  //  Включаем подсветку LCD дисплея
  //Serial.begin(115200);
  int8_t data_test [] = {1, 40, 100, 1, 78, 100, 1, 80, 100}; // Удалить
  EEPROM.put(100, data_test); //Удалить
}

void loop() {  
  butt_DOWN.tick(); 
  butt_RIGHT.tick();
  butt_UP.tick();
  butt_OK.tick();

  lcd.setCursor(6, 0);
  lcd.print("Main menu");
  lcd.setCursor(3, 1);
  lcd.print("Program selection");
  lcd.setCursor(3, 2);
  lcd.print("Program editing");
  lcd.setCursor(3, 3);
  lcd.print("Manual mode");

  lcd.setCursor(0, main_ptr);
  lcd.print("->");  
  
  if (butt_DOWN.click()) {
    lcd.setCursor(0, main_ptr);
    lcd.print("  ");
    main_ptr++;
    if (main_ptr == 4) main_ptr = 1;
  }
  if (butt_UP.click()) {
    lcd.setCursor(0, main_ptr);
    lcd.print("  ");
    main_ptr--;
    if (main_ptr == 0) main_ptr = 3;
  }
  if (butt_OK.click() || butt_RIGHT.click()) {
    if (main_ptr == 1) { Program_selection(); }
    if (main_ptr == 2) { Program_editing(); }
    if (main_ptr == 3) { Manual_mod(); }
  }
}

void get_temp() { 
  static uint32_t temp_timer = 0;
  if (millis() - temp_timer >= 1000) {
    temp_timer = millis();
    DHT.read22(DHT22_PIN);         //Удалить
    cur_temp = DHT.temperature;         //Удалить
    /*if (ds.readTemp()) {           //Раскоментировать
      cur_temp = ds.getTemp();
      ds.requestTemp();
    }*/                               //Раскоментировать
  }
}

void Program_selection() {  
  
  lcd.clear();
  for (end_loop = false; !end_loop;) {         
    lcd.setCursor(2, 0);
    lcd.print("Program selection");
    Program_menu();    
    if (butt_OK.click()) {
      int8_t data [3];
      int8_t prev_temp;
      EEPROM.get(program_ptr * 100, data);
      int8_t amt = data[0]; 
      bool prog_correct = false; //Проверка корректности записанной программы
      if (amt > 0 && amt <10) prog_correct = true; // Количество пауз
      for (int8_t i = 0; i <= amt && prog_correct; i++) {
        if (i == 0) {
          if (data [1] < 20 || data [1] > 100) prog_correct = false; // температура
          if (data [2] < 10 || data [2] > 100) prog_correct = false; //мощность
        }else{
          EEPROM.get(program_ptr * 100 + i * 3, data);
          if (data [0] < 1 || data [0] > 120) prog_correct = false; //длительность
          if (data [1] < prev_temp || data [1] > 100) prog_correct = false; // температура
          if (data [2] < 10 || data [2] > 100) prog_correct = false; //мощность
        }
        prev_temp = data [1]; 
      }  // Конец проверки корректности программы
      
      if (prog_correct){
        bool flag = false; // Флаг выхода на температурный режим 
        uint32_t Tmr_ms;   //Таймер температурного режима       
        lcd.clear(); 
        EEPROM.get(program_ptr * 100, data);      
        for(uint8_t pause_ptr = 0; pause_ptr <= amt + 1;){
          get_temp();
          heat(data[1], data[2]);
          if ((cur_temp > data[1] - 0.5 || pause_ptr == amt + 1) && !flag){
           flag = true;
           Tmr_ms = millis();
          }
          lcd.setCursor(1, 0);
          lcd.print("Program ");
          lcd.print(program_ptr);
          if (pause_ptr == 0){
            lcd.print(" Heating");          
          }else if (pause_ptr == amt + 1){
            lcd.print(" finished");
          }else{
            lcd.print(" Pause ");
            lcd.print(pause_ptr);
          }
          lcd.setCursor(0, 1);
          lcd.print("Set temp.  ");
          lcd.print(data[1]);
          lcd.print(char(223));
          lcd.print("C");
          lcd.setCursor(0, 2);
          lcd.print("Cur. temp. ");
          lcd.print(cur_temp, 1);
          lcd.print(char(223));
          lcd.print("C");
          if (flag){
            uint16_t Tmr_s = floor((millis() - Tmr_ms)/1000);
            if(Tmr_s % 4 < 2 && Tmr_s < 10) analogWrite(buzzer_pin, 127); //Пищалка
            if(Tmr_s % 4 > 1 && Tmr_s <= 10) digitalWrite(buzzer_pin, LOW);
            lcd.setCursor(0, 3);
            if (pause_ptr == 0){              
              lcd.print("Add malt & press Ok");
              butt_OK.tick();
              if (butt_OK.click()){
                pause_ptr++;
                EEPROM.get(program_ptr * 100 + pause_ptr * 3, data); 
                flag = false;
                lcd.clear();
                digitalWrite(buzzer_pin, LOW);
              }              
            } else if (pause_ptr == amt + 1) { 
              lcd.print((Tmr_s / 3600) % 10);
              lcd.print(":");
              lcd.print((Tmr_s / 600) % 6);
              lcd.print((Tmr_s / 60) % 10);
              lcd.print(":");
              lcd.print((Tmr_s / 10) % 6);
              lcd.print(Tmr_s % 10);             
              lcd.print("    Press Ok");
              butt_OK.tick();
              if (butt_OK.click()){
                pause_ptr++;
                flag = false;
                digitalWrite(buzzer_pin, LOW);
                lcd.clear();
              }            
            } else{
              lcd.print("Timer ");
              lcd.print(((data[0] * 60 - Tmr_s) / 3600) % 10);
              lcd.print(":");
              lcd.print(((data[0] * 60 - Tmr_s) / 600) % 6);
              lcd.print(((data[0] * 60 - Tmr_s) / 60) % 10);
              lcd.print(":");
              lcd.print(((data[0] * 60 - Tmr_s) / 10) % 6);
              lcd.print((data[0] * 60 - Tmr_s) % 10);
              if (data[0] * 60 - Tmr_s <= 0){
                pause_ptr++;
                if (pause_ptr <= amt) {
                  EEPROM.get(program_ptr * 100 + pause_ptr * 3, data);                  
                }              
                flag = false;
                lcd.clear();
              }
            }            
          }          
        }
        digitalWrite(heater_pin, LOW); 
      } else {
        lcd.clear();
        for(;;) {
          butt_OK.tick();
          lcd.setCursor(1, 1);
          lcd.print("Program incorrect");
          lcd.setCursor(6, 3);
          lcd.print("Press OK");
          if (butt_OK.click()) break;
        }
        lcd.clear();
      }
    }
  }
}

void Program_editing() {  
  lcd.clear();
  for (end_loop = false; !end_loop;) {       
    lcd.setCursor(2, 0);
    lcd.print("Program editing");
    Program_menu();    
    if (butt_OK.click()) {
      lcd.clear();
      int8_t data [3];                         //Массив
      EEPROM.get(program_ptr * 100, data);
      
      bool edit = false;                      // Флаг режима редактирования    
      uint8_t amt = 1;  
      int8_t int_ptr = 1;
      for(int8_t pause_ptr = 0; pause_ptr >= 0 && pause_ptr <= amt;){
               
        butt_DOWN.tick();
        butt_LEFT.tick();
        butt_RIGHT.tick();
        butt_UP.tick();
        butt_OK.tick();
        data[1] = constrain(data[1], 20, 80);
        data[2] = constrain(data[2], 10, 100);
        if (pause_ptr == 0){
          data[0] = constrain(data[0], 1, 9);
          amt = data[0];
          lcd.setCursor(5, 0);
          lcd.print("Program ");
          lcd.print(program_ptr);
          lcd.setCursor(1, 1);
          lcd.print("Amt of pauses  ");
          lcd.print(data[0]);
          lcd.setCursor(1, 2);
          lcd.print("Pour temp.    ");
        } else {
          data[0] = constrain(data[0], 0, 120);         
          lcd.setCursor(2, 0);
          lcd.print("Program ");
          lcd.print(program_ptr);
          lcd.print(" Pause ");
          lcd.print(pause_ptr);
          lcd.setCursor(1, 1);
          lcd.print("Duration    ");
          lcd.print(data[0]);
          lcd.print("min ");
          lcd.setCursor(1, 2);
          lcd.print("Temperature  ");
        }
        lcd.print(data[1]);
        lcd.print(char(223));
        lcd.print("C ");
        lcd.setCursor(1, 3);
        lcd.print("Heater power  ");
        lcd.print(data[2]);
        lcd.print("% ");
        
        lcd.setCursor(0, int_ptr);
        if (edit) lcd.print("!"); else lcd.print(">");

        if (butt_DOWN.click()) {
          if (edit) data[int_ptr - 1]--; else {
            lcd.setCursor(0, int_ptr);
            lcd.print(" ");
            int_ptr++;
            if (int_ptr == 4) int_ptr = 1;
          }
        }
        if (butt_UP.click()) {
          if (edit) data[int_ptr-1]++; else {
            lcd.setCursor(0, int_ptr);
            lcd.print(" ");
            int_ptr--;
            if (int_ptr == 0) int_ptr = 3;
          }
        }
        if (butt_LEFT.click()) {
          if (edit) data[int_ptr-1]-=10; else {
            EEPROM.put(program_ptr * 100 + pause_ptr * 3, data);            
            pause_ptr--;
            EEPROM.get(program_ptr * 100 + pause_ptr * 3, data);
            int_ptr = 1;
            lcd.clear();
          }
        }
        if (butt_RIGHT.click()) {
          if (edit) data[int_ptr - 1] += 10; else {
            EEPROM.put(program_ptr * 100 + pause_ptr * 3, data);            
            pause_ptr++;
            EEPROM.get(program_ptr * 100 + pause_ptr * 3, data);
            int_ptr = 1;
            lcd.clear();
          }
        }
        if (butt_OK.click()) {          
          edit = !edit;
        }
      }      
    }           
  }
}

void Program_menu() {
  butt_DOWN.tick();
  butt_LEFT.tick();
  butt_RIGHT.tick();
  butt_UP.tick();
  butt_OK.tick();

  for (uint8_t i = 1; i <= 9; i++) {  //Отрисовываем меню
    if (i < 4) {
      lcd.setCursor(3, i);
      lcd.print("Pr");
      lcd.print(i);
    } else if (i > 6) {
      lcd.setCursor(17, i - 6);
      lcd.print("Pr");
      lcd.print(i);
    } else {
      lcd.setCursor(10, i - 3);
      lcd.print("Pr");
      lcd.print(i);
    }
  }

  if (program_ptr < 4) {  //отрисовываем указатель
    lcd.setCursor(0, program_ptr);
  } else if (program_ptr > 6) {
    lcd.setCursor(14, program_ptr - 6);
  } else {
    lcd.setCursor(7, program_ptr - 3);
  }
  lcd.print("->");

  if (butt_DOWN.click()) {
    if (program_ptr < 4) {
      lcd.setCursor(0, program_ptr);
    } else if (program_ptr > 6) {
      lcd.setCursor(14, program_ptr - 6);
    } else {
      lcd.setCursor(7, program_ptr - 3);
    }
    lcd.print("  ");
    program_ptr++;
    if (program_ptr == 10) program_ptr = 1;
  }

  if (butt_UP.click()) {
    if (program_ptr < 4) {
      lcd.setCursor(0, program_ptr);
    } else if (program_ptr > 6) {
      lcd.setCursor(14, program_ptr - 6);
    } else {
      lcd.setCursor(7, program_ptr - 3);
    }
    lcd.print("  ");
    program_ptr--;
    if (program_ptr == 0) program_ptr = 9;
  }

  if (butt_RIGHT.click()) {
    if (program_ptr < 4) {
      lcd.setCursor(0, program_ptr);
    } else if (program_ptr > 6) {
      lcd.setCursor(14, program_ptr - 6);
    } else {
      lcd.setCursor(7, program_ptr - 3);
    }
    lcd.print("  ");
    program_ptr += 3;
    program_ptr = constrain(program_ptr, 1, 9);
  }

  if (butt_LEFT.click()) {
    if (program_ptr < 4) {
      lcd.clear();
      end_loop = true;      
    } else if (program_ptr > 6) {
      lcd.setCursor(14, program_ptr - 6);
    } else {
      lcd.setCursor(7, program_ptr - 3);
    }
    if (!end_loop) {
      lcd.print("  ");
      program_ptr -= 3;
    }
  }
}

void Manual_mod() { //Ручной режим
  lcd.clear(); 
  
  int8_t ptr = 1;    // Указатель
  bool edit = false; // режим редактирования
  bool flag = false; // Флаг выхода на температурный режим
  uint32_t Tmr_ms;   //Таймер температурного режима
  static int8_t temp_pow[] = {50, 80};   // температура, мощность
  bool heater_on = false; //Нагреватель выключен

  for (;;) {
    
    butt_DOWN.tick();
    butt_LEFT.tick();
    butt_RIGHT.tick();
    butt_UP.tick();
    butt_OK.tick();      

    
    if (butt_DOWN.click()){
      if(edit) {
        temp_pow[ptr-1]--;
        if(ptr == 1 && flag){
          flag = false;
          digitalWrite(buzzer_pin, LOW);
          lcd.setCursor(15, 0);
          lcd.print("     ");
        } 
      } else {        
        lcd.setCursor(0, ptr);
        lcd.print("  ");        
        ptr++;
        if(ptr == 4) ptr=1;
      }    
    }

    if (butt_UP.click()){
      if (edit) {
        temp_pow[ptr-1]++;
        if(ptr == 1 && flag){
          flag = false;
          digitalWrite(buzzer_pin, LOW);
          lcd.setCursor(15, 0);
          lcd.print("     ");
        }  
      } else{  
        lcd.setCursor(0, ptr);
        lcd.print("  ");
        ptr--;
        if(ptr == 0) ptr=3;
      }    
    }

    if (butt_RIGHT.click() ){      
      if(edit){
        temp_pow[ptr-1]+=10;
        if(ptr == 1 && flag){
          flag = false;
          digitalWrite(buzzer_pin, LOW);
          lcd.setCursor(15, 0);
          lcd.print("     ");
        } 
      } else {
        if(ptr == 3) heater_on = !heater_on;
        else edit = true;   
      }    
    }

    if (butt_LEFT.click()){      
      if(edit){
        temp_pow[ptr-1]-=10;
        if(ptr == 1 && flag){
          flag = false;
          digitalWrite(buzzer_pin, LOW);
          lcd.setCursor(15, 0);
          lcd.print("     ");
        } 
      }
      else { 
        digitalWrite(heater_pin, LOW);
        break;
      }
    } 

    if (butt_OK.click()){
      if(ptr == 3) heater_on = !heater_on; 
      else edit = !edit;    
    }

    temp_pow[0] = constrain(temp_pow[0], 20, 100);
    temp_pow[1] = constrain(temp_pow[1], 10, 100);

    lcd.setCursor(3, 0);
    lcd.print("Manual mode ");
    lcd.setCursor(2, 1);
    lcd.print("Set temp.    ");
    if (temp_pow[0] < 100) lcd.print(" ");
    lcd.print(temp_pow [0]);
    lcd.print(char(223));
    lcd.print("C");    
    
    lcd.setCursor(2, 2);
    lcd.print("Heater power  ");
    if (temp_pow[1] < 100) lcd.print(" ");
    lcd.print(temp_pow [1]);
    lcd.print("%");
    
    lcd.setCursor(2, 3);
    if (heater_on){
      lcd.print("Heater ON  ");
      } else {
      lcd.print("Heater OFF ");
      }
    get_temp();
    if (cur_temp < 100) lcd.print(" ");
    if (cur_temp < 10) lcd.print(" ");
    lcd.print(cur_temp, 1);
    lcd.print(char(223));
    lcd.print("C");

    if (cur_temp > temp_pow[0] - 0.5 && !flag){
      flag = true;
      Tmr_ms = millis();
    }
    if (flag){      
      uint16_t Tmr_s = floor((millis() - Tmr_ms)/1000);
      if (Tmr_s >= 6000) Tmr_ms = millis();    
      lcd.setCursor(15, 0);
      lcd.print((Tmr_s / 600) % 10);
      lcd.print((Tmr_s / 60) % 10);
      lcd.print(":");
      lcd.print((Tmr_s / 10) % 6);
      lcd.print(Tmr_s % 10);
      if(Tmr_s % 4 < 2 && Tmr_s < 10) analogWrite(buzzer_pin, 127); //Пищалка
      if(Tmr_s % 4 > 1 && Tmr_s <= 10) digitalWrite(buzzer_pin, LOW);
    }

    lcd.setCursor(0, ptr);
    if (edit) lcd.print("! "); 
    else lcd.print("->"); 

    if (heater_on) heat(temp_pow[0], temp_pow[1]);
    else digitalWrite(heater_pin, LOW);  
  }
  lcd.clear();
}
void heat(int8_t set_temp, int8_t power){
  
  static uint16_t activePeriod = 0;
  static uint32_t pwm_tmr = 0; 

  if (millis() - pwm_tmr >= 1000) {
    pwm_tmr = millis();    
    if (set_temp < 100){ // пид регулятор      
      const float kp = 25;
      const float ki = 0.3;
      const float kd = 15;
      static float integral = 0, prevErr = 0;

      float err = set_temp - cur_temp; // Пропорциональная составляющая        
      integral = constrain(integral + err, (-2 - fabs(err) * 10), (2 + 10 * fabs(err))); //Интегральная составляющая
      float D = err - prevErr; //Дифференциальная состовляющая
      prevErr = err;
      activePeriod = round(constrain(err * kp + integral * ki + D * kd, 0, power)) * 10;
      Serial.print(cur_temp);
      Serial.print("   ,");
      Serial.print(err);
      Serial.print("    ,");
      Serial.print(err * kp);
      Serial.print("   ,");             
      Serial.print(integral * ki);
      Serial.print("   ,");
      Serial.print(D * kd);
      Serial.print("     ,");
      Serial.println(activePeriod/10);
    } else { 
      activePeriod = power * 10;      
    }
  }
  if (millis() - pwm_tmr < activePeriod) digitalWrite(heater_pin, HIGH);
  else {
    digitalWrite(heater_pin, LOW);    
  }
}