// Load Library
#include "HX711.h"
#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>
#include <ArduinoJson.h>

Servo servo1;  
Servo servo2;  
int pos = 0;
const int LOADCELL_DOUT_PIN = 18;
const int LOADCELL_SCK_PIN = 5;
const int servoPin1 = 19;
const int servoPin2 = 21;
int GRAM;
int grade_a;
int grade_b;
int grade_c;
HX711 scale;
StaticJsonDocument<256> json_data;

// MQTT Broker
const char *mqtt_broker = "0.tcp.ap.ngrok.io";
const char *topic = "rusa";
const int mqtt_port = 19609;

WiFiClient espClient;
PubSubClient client(espClient);

void setup() {
  Serial.begin(9600);
  Serial.println("Initializing the scale");
  scale.begin(LOADCELL_DOUT_PIN, LOADCELL_SCK_PIN);
  servo1.attach(servoPin1, 500, 2400);
  servo2.attach(servoPin2, 500, 2400);
  // connecting to a WiFi network
  WiFi.begin("Wokwi-GUEST", "", 6);
  while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.println("Connecting to WiFi..");
  }
  Serial.println("Connected to the WiFi network");
  //connecting to a mqtt broker
  client.setServer(mqtt_broker, mqtt_port);
  client.setCallback(callback);
  while (!client.connected()) {
      String client_id = "esp32-client-";
      client_id += String(WiFi.macAddress());
      Serial.printf("The client %s connects to the public mqtt broker\n", client_id.c_str());
      if (client.connect(client_id.c_str())) {
          Serial.println("Public ngrok mqtt broker connected");
      } else {
          Serial.print("failed with state ");
          Serial.print(client.state());
          delay(2000);
      }
  }
}

void callback(char *topic, byte *payload, unsigned int length) {
  Serial.print("Message arrived in topic: ");
  Serial.println(topic);
  Serial.print("Message:");
  for (int i = 0; i < length; i++) {
      Serial.print((char) payload[i]);
  }
  Serial.println();
  Serial.println("-----------------------");
}

void loop() {

//Calculate Gram value from HX711 sensor 
  GRAM = (scale.get_units()/420)*1000;
  char message[128];

  if (GRAM >= 60){
    //condition grade A egg
    servo1.write(60);
    servo2.write(60);
    grade_a++;
  }else if(GRAM >= 50 && GRAM < 60) {
    //condition grade B egg
    servo1.write(90);
    servo2.write(90);
    grade_b++;
  }else if(GRAM >= 30 && GRAM < 50) {
    //condition grade C egg
    servo1.write(120);
    servo2.write(120);
    grade_c++;
  } else {
    //assigning a value 
      json_data["grade_a"] = grade_a; 
      json_data["grade_b"] = grade_b; 
      json_data["grade_c"] = grade_c; 
      if(grade_a > 0 || grade_b > 0 || grade_c > 0){
        //sending data over a network
        serializeJson(json_data, message);
        client.publish(topic, message);
        Serial.print("Akumulasi Grade A:");
        Serial.println(grade_a);
        Serial.print("Akumulasi Grade B:");
        Serial.println(grade_b);
        Serial.print("Akumulasi Grade C:");
        Serial.println(grade_c);
      }
      //initializing the variable o the value of 0
      grade_a = 0;
      grade_b = 0;
      grade_c = 0;
  }
  client.loop();  

  delay(1000);                                                                                
}