#include <WiFi.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <ESP32Servo.h>
#include "time.h"
#include <CuteBuzzerSounds.h>
#include <PubSubClient.h>

LiquidCrystal_I2C LCD = LiquidCrystal_I2C(0x27, 16, 2);
#define ECHO_PIN 13
#define TRIG_PIN 12
#define BUTTON_PIN 23
#define SERVO_PIN 15
#define BUZZER_PIN 14

int lastState = HIGH;
int valueServo = HIGH;
int pos = 90;
const char* mqtt_server = "test.mosquitto.org";
int port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE (50)
char msg[MSG_BUFFER_SIZE];

Servo servo;

void spinner() {
  static int8_t counter = 0;
  const char* glyphs = "\xa1\xa5\xdb";
  LCD.setCursor(15, 1);
  LCD.print(glyphs[counter++]);
  if (counter == strlen(glyphs)) {
    counter = 0;
  }
}

void setTimezone(String timezone){
  Serial.printf("  Setting Timezone to %s\n",timezone.c_str());
  setenv("TZ",timezone.c_str(),1);  //  Now adjust the TZ.  Clock settings are adjusted to show the new local time
  tzset();
}

void initTime(String timezone){
  struct tm timeinfo;

  Serial.println("Setting up time");
  configTime(0, 0, "id.pool.ntp.org");    // First connect to NTP server, with 0 TZ offset
  if(!getLocalTime(&timeinfo)){
    Serial.println("  Failed to obtain time");
    LCD.setCursor(0, 0);
    LCD.println("Con Err");
    cute.play(S_DISCONNECTION);
    return;
  }
  Serial.println("  Got the time from NTP");
  // Now we can set the real timezone
  setTimezone(timezone);
}

void printLocalTime(){
  struct tm timeinfo;
  if(!getLocalTime(&timeinfo)){
    LCD.setCursor(0, 1);
    LCD.println("Error");
    return;
  }

  LCD.setCursor(8, 0);
  LCD.println(&timeinfo, "%H:%M:%S");
}

int readDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  int duration = pulseIn(ECHO_PIN, HIGH);
  return duration * 0.034 / 2;
}

void callback(char* topic, byte* payload, unsigned int length) { //perintah untuk menampilkan data ketika esp32 di setting sebagai subscriber
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) { //mengecek jumlah data yang ada di topik mqtt
    Serial.print((char)payload[i]);
  }
  Serial.println();
  openServo();
}

void reconnect() { //perintah koneksi esp32 ke mqtt broker baik itu sebagai publusher atau subscriber
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // perintah membuat client id agar mqtt broker mengenali board yang kita gunakan
    String clientId = "CatFeeder-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      // Once connected, publish an announcement...
      client.publish("/catfeeder/kapasitas", "CatFeeder"); //perintah publish data ke alamat topik yang di setting
      // ... and resubscribe
      client.subscribe("/catfeeder/servo"); //perintah subscribe data ke mqtt broker
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void openServo() {
    Serial.println("### MAKANAN KELUAR ###");

    LCD.setCursor(0, 1);
    LCD.println("Makanan Keluar ");

    cute.play(S_SURPRISE);

    for (pos = 90; pos <= 180; pos += 1) {
      servo.write(pos);
      spinner();
      delay(1);
    }
    
    delay(500);

    for (pos = 180; pos >= 90; pos -= 1) {
      servo.write(pos);
      spinner();
      delay(1);
    }

    cute.play(S_HAPPY);
}

void setup() {
  Serial.begin(115200);
  pinMode(BUZZER_PIN, OUTPUT);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  servo.attach(SERVO_PIN, 500, 2400);

  cute.init(BUZZER_PIN);

  LCD.init();
  LCD.backlight();
  LCD.setCursor(0, 0);
  LCD.print("Connecting to ");
  LCD.setCursor(0, 1);
  LCD.print("WiFi ");

  WiFi.begin("Wokwi-GUEST", "", 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(250);
    spinner();
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  LCD.clear();
  LCD.setCursor(0, 0);
  LCD.println("Online");
  LCD.setCursor(0, 1);
  LCD.println("Updating time...");

  cute.play(S_CONNECTION);

  initTime("WIB-7");   // Set for Asia/Jakarta
  printLocalTime();

  client.setServer(mqtt_server, 1883); //perintah connecting / koneksi awal ke broker
  client.setCallback(callback); //perintah menghubungkan ke mqtt broker untuk subscribe data
}

void loop() {
  int distance = readDistance();
  int kapasitas = distance * 2; // tinggi max penampung 50cm

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  // ambil input button
  int value = digitalRead((BUTTON_PIN));

  // gerakan servo
  if (lastState != value || lastState != valueServo) {
    openServo();    
  }

  LCD.setCursor(0, 1);
  LCD.println("Kapasitas: ");
  LCD.print(kapasitas);
  LCD.print("%");

  printLocalTime();

  snprintf (msg, MSG_BUFFER_SIZE, "%ld", kapasitas); //perintah mempersiapkan data untuk dikirim ke mqtt broker
    Serial.print("Publish message: ");
    Serial.println(msg);
    client.publish("/catfeeder/kapasitas", msg); //perintah publish data ke mqtt broker, yang di publish data dalam variabel msg boleh diubah-ubah

  delay(100);
}