// Dimming PSEUDO-LOGARITMICO: variazioni diverse per ogni step secondo la curva simil CIE1931
/*
  Secondo la curva CIE1931 la Luminosità (in inglese brightness: cioè la luce "percepita" nel range 0%-100% )
  dipende dalla Luminanza (in inglese luminance: grandezza misurabile, cioè quella che andiamo ad impostare noi)
  secondo le seguenti formule:

  Brightness = 116 * Luminance ^ (1/3) - 16         for luminance levels above 0.008856
  Brightness = 902.3 * Luminance                    for luminance levels at or below 0.008856
*/

const uint8_t PROGMEM gamma8[] = {
    0,  1,  1,  1,  1,  1,  1,  1,  1,  1,  1,  1,  1,  1,  1,  1,
    1,  1,  1,  1,  1,  1,  1,  1,  2,  2,  2,  2,  2,  2,  2,  2,
    2,  2,  2,  2,  2,  2,  2,  2,  2,  2,  2,  3,  3,  3,  3,  3,
    3,  3,  3,  3,  3,  3,  3,  3,  4,  4,  4,  4,  4,  5,  5,  5,
    5,  6,  6,  6,  6,  7,  7,  7,  7,  8,  8,  8,  9,  9,  9, 10,
   10, 10, 11, 11, 11, 12, 12, 13, 13, 13, 14, 14, 15, 15, 16, 16,
   17, 17, 18, 18, 19, 19, 20, 20, 21, 21, 22, 22, 23, 24, 24, 25,
   25, 26, 27, 27, 28, 29, 29, 30, 31, 32, 32, 33, 34, 35, 35, 36,
   37, 38, 39, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 50,
   51, 52, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 66, 67, 68,
   69, 70, 72, 73, 74, 75, 77, 78, 79, 81, 82, 83, 85, 86, 87, 89,
   90, 92, 93, 95, 96, 98, 99,101,102,104,105,107,109,110,112,114,
  115,117,119,120,122,124,126,127,129,131,133,135,137,138,140,142,
  144,146,148,150,152,154,156,158,160,162,164,167,169,171,173,175,
  177,180,182,184,186,189,191,193,196,198,200,203,205,208,210,213,
  215,218,220,223,225,228,231,233,236,239,241,244,247,249,252,255
};


uint8_t getDimmerVal(uint8_t step) {
  return pgm_read_byte(&gamma8[step]);
}

#define FADE_IN 3
#define FADE_OUT 2
#define LED_OUT 11

#define MAX_DIM_TIME 10000

unsigned int dimTime;
unsigned int stepTime;

bool fadeIn = false;
bool fadeOut = false;

unsigned char stepNum;

void setup() {
  Serial.begin(115200);
  pinMode(LED_OUT, OUTPUT);
	pinMode(FADE_OUT, INPUT_PULLUP);
	pinMode(FADE_IN, INPUT_PULLUP);

	uint8_t dim = getDimmerVal(stepNum);
  analogWrite(LED_OUT, dim);
}


void loop()  { 
  dimTime = map(analogRead(A0), 0, 1023, 10, MAX_DIM_TIME);
	stepTime = (unsigned int) dimTime / sizeof(gamma8);

	static unsigned long doStepTime;

	// Fade in non bloccante del led
	if ((millis() - doStepTime > stepTime) && fadeIn) {		
		doStepTime = millis();		
		stepNum++;	    
		uint8_t dim = getDimmerVal(stepNum);
    analogWrite(LED_OUT, dim);					
		fadeIn = (stepNum < 255);

		// Serial.print(stepNum);
		// Serial.print(" - ");
		// Serial.println(dim);
	}

	// Fade out non bloccante del led
	if ((millis() - doStepTime > stepTime) && fadeOut) {		
		doStepTime = millis();		
    stepNum--;	
		uint8_t dim = getDimmerVal(stepNum);
    analogWrite(LED_OUT, dim);		
		fadeOut = (stepNum > 0);

		// Serial.print(stepNum);
		// Serial.print(" - ");
		// Serial.println(dim);
	}

	// Lettura dello stato del pulsante con debounce
  static unsigned long debounceTime;  	 
  if (!digitalRead(FADE_IN) && millis() - debounceTime > 200) {    
    debounceTime = millis();
    fadeOut = false;	
		fadeIn = true;			
		Serial.print("Fade in. Tempo step(ms): ");	
		Serial.println(stepTime);
  }
	if (!digitalRead(FADE_OUT) && millis() - debounceTime > 200) {    
    debounceTime = millis();
    fadeOut = true;	
		fadeIn = false;	
		Serial.print("Fade out. Tempo step(ms): ");	
		Serial.println(stepTime);
  }

}