// Example 3 - Receive with start- and end-markers

const byte numChars = 32;
char receivedChars[numChars];

boolean newData = false;

void setup() {
  Serial.begin(9600);
  Serial.println("<Arduino is ready>");
}

void loop() {
  recvWithStartEndMarkers();
  showNewData();
}

void recvWithStartEndMarkers() {
  static boolean recvInProgress = false;
  static byte ndx = 0;
  char startMarker = '<';
  char endMarker = '>';
  char rc;

  while (Serial.available() > 0 && newData == false) {
    rc = Serial.read();

    if (recvInProgress == true) {
      if (rc != endMarker) {
        receivedChars[ndx] = rc;
        ndx++;
        if (ndx >= numChars) {
          ndx = numChars - 1;
        }
      }
      else {
        receivedChars[ndx] = '\0'; // terminate the string
        recvInProgress = false;
        ndx = 0;
        newData = true;
      }
    }

    else if (rc == startMarker) {
      recvInProgress = true;
    }
  }
}

void showNewData() {
  if (newData == true) {

    newData = false;

    if (strcmp(receivedChars, "verde") == 0) {
      Serial.print("This just in ... ");
      Serial.println(receivedChars);
    }
    else if (strcmp(receivedChars, "rojo") == 0) {
      Serial.print("This just in ... ");
      Serial.println(receivedChars);
    }
    else if (strcmp(receivedChars, "azule") == 0) {
      Serial.print("This just in ... ");
      Serial.println(receivedChars);
    }

  }
}