/*  debug file:
 *
 *  Find the 4 bugs in this programme and debug them. 
 *
 *  created 25.01.2022  by Mike Kramler, TUMlab, Munic
 *  modified 07.03.2022  by Marion Pellowski, TUMlab, Munic
 */

#include "tumlab.h"     // Include class definitions

Light ledRed(13);       // creating an object: red LED
Light ledYellow(12);    // creating an object: yellow LED
Light ledGreen(11);     // creating an object: green LED

void setup() {
  // remains empty for now
}

void loop() { 
  ledGreen.go(HIGH);    // Switches green LED on
  delay(500);           // waits for 500 milliseconds
  ledGreen.go(LOW);     // Switches green LED off
  ledYellow.go(HIGH);   // ...
  delay(500);         
  ledYellow.go(LOW);
  ledRed.go(HIGH);   
  delay(500);
  ledRed.go(LOW);
  ledYellow.go(HIGH);   
  delay(500);
  ledYellow.go(LOW);
};


wokwi-LEDs-en.ino

diagram.json

/* 
 *  Klassendefinition Drehscheibe   TUMlab 25.01.2022
 */
#include "Arduino.h"    //unbedingt erforderlich
#include <Servo.h>      //Servo-Bibliothek

class Light{   //Name für die Klasse
  //legt ein digitales Objekt an, das ein- und ausgeschaltet werden kann
  //Konstruktor erwartet Pin-Nr.
  //Methode go(bool): HIGH schaltet ein, LOW schaltet aus
  
  private:          //nur innerhalb dieser Klasse zu nutzen:
  int ledPin;       //Pin für digitale Signalausgabe

  public:           //von außerhalb der Klasse erreichbar
  Light(int new_pin){   //Konstruktor erwartet Pin-Nummer
    ledPin = new_pin;   //entgegengenommenen Wert in Variable schreiben
    pinMode(ledPin,OUTPUT);     //Pin als Ausgang festlegen
  }

  void go(bool onoff){ //ein- u ausschalten des dig. Ausgangs
        //onoff HIGH schaltet ein, onoff LOW schaltet aus
    digitalWrite(ledPin,onoff);
  }
};             //Semikolon am Klassenende nicht vergessen

class Motor{   //Name für die Klasse
  //legt ein Motor-Objekt an, das digital ein- und ausgeschaltet 
  //  werden kann oder analog mit reduzierter Geschwindigkeit
  //Konstruktor erwartet Pin-Nr.
  //Methode go(bool): HIGH schaltet ein, LOW schaltet aus
  //Methode goSlow(int): schaltet mit gewählter Geschwindigkeit ein
  //  (int) im Bereich von 100 bis 255, 
  //        bei kleineren Werten läuft der Motor nicht an
  //  ausschalten mit Geschwindigkeit 0
  
  private:          //nur innerhalb dieser Klasse zu nutzen:
  int motPin;       //Pin für digitale Signalausgabe

  public:           //von außerhalb der Klasse erreichbar
  Motor(int new_pin){   //was in der ino im setup() passiert
    motPin = new_pin;   //entgegengenommenen Wert in Variable schreiben
    pinMode(motPin,OUTPUT);     //Pin als Ausgang festlegen
  }

  void go(bool onoff){ //ein- u ausschalten des dig. Ausgangs
        //onoff HIGH schaltet ein, onoff LOW schaltet aus
    digitalWrite(motPin,onoff);
  }

  void goSlow(int velocity){ //Motorgeschwindigkeit 0-255
    analogWrite(motPin,velocity);
  }
};             //Semikolon am Klassenende nicht vergessen

class ServoMotor{ //Name für die Klasse Servo
  //legt ein ServoObjekt an und dreht auf Pos 1 oder Pos 2
  //Konstruktor erwartet Pinnummer, Low-Pos und High-Pos
  //  die Positionen sind Winkel zwischen 0 und 180
  //Methode go() dreht den Servo mit maximaler Geschwindigkeit
  //Methode goSlow() dreht mit reduzierter Geschwindigkeit.
  
  private:    //nur innerhalb der Klasse verfügbar:
  int srvPin;     //ServoPin
  int loPos;      //Servo Low-Position (Winkel Ruheposition)
  int hiPos;      //Servo High-Position (Winkel Kugelausgabe)
  int iteration;  //Zählrichtung für Methode goSlow()

  public:     //aus Programmcode (ino) aufrufbar:
  Servo srv;
  //Konstruktor
  ServoMotor(int new_pin, int new_loPos, int new_hiPos){
    srvPin = new_pin;       //Pinnummer des Servos kopieren
    loPos = new_loPos;      //Ruheposition Winkel in Grad
    hiPos = new_hiPos;      //Position Kugelausgabe in Grad
    if(hiPos>loPos)         //ist der HIGH-Winkel der größere
      iteration=1;          //dann hochzählen
    else                    //ist der LOW-Winkel der größere
      iteration=-1;         //dann runterzählen
  }

  void go(bool pos){        //pos HIGH oder LOW
    srv.attach(srvPin);     //Servo einhängen
    if(pos==HIGH){          //pos HIGH:
      srv.write(hiPos);     //Position Kugelausgabe anfahren
    }else{                  //pos LOW:
      srv.write(loPos);     //Ruheposition anfahren
    }
    delay(300);             //Bewegung des Servos abwarten
    srv.detach();           //Servo aushängen, spart Strom
  }
  
  void goSlow(bool pos){    //langsame Servobewegung
    srv.attach(srvPin);     //Servo einhängen
    if(pos==HIGH){          //pos HIGH: Richtung AktivPosition
      for(int i=loPos; i!=hiPos; i=i+iteration){  //dann zähle aufwärts
        srv.write(i);       //nächsten Schritt anfahren
        delay(10);}         //Bewegung verlangsamen
    }else{                  //pos LOW: Richtung Ruheposition
      for(int i=hiPos; i!=loPos; i=i-iteration){  //dann zähle abwärts
        srv.write(i);       //nächsten Schritt anfahren
        delay(10);}         //Bewegung verlangsamen       
    }
    delay(30);              //letzten Schritt des Servos abwarten
    srv.detach();           //Servo aushängen, spart Strom   
  }
};                  //Semikolon am Klassenende nicht vergessen

class ReflexSensor{  //Name für die Klasse
  //legt ein Objekt an, bestehend aus LED und LDR an
  //Kostruktor erwartet PinNr der LED, PinNr des LDR und einen Schwellwert
  // je kleiner der Schwellwert, umso empfindlicher reagiert die Lichtschranke
  //Konstruktor kann auch nur mit LDR-Pin aufgerufen werden
  //Methode waitForCan() ist ein Wartebefehl!!! Wartet auf Erkennen eines Bechers
  //Methode detectCan() gibt HIGH zurück, wenn ein Becher erkannt wird
  //Methode showValues() schickt Messwerte an den Seriellen Plotter,
  //  dient nur zum Test und zum Betrachten der Messwerte
  //Methode showLDR() schickt nur den LDR-Messwert an den Seriellen Plotter,
  //  dient nur zum Ausprobieren des LDRs
 
  private:           //nur innerhalb der Klasse nutzbar:
  int ledPin, ldrPin, threshold, ledOn, ledOff; 

  public:
  //Konstruktor für die Reflexlichtschranke
  ReflexSensor(int new_ledPin, int new_ldrPin, int new_threshold){
    ledPin = new_ledPin;
    ldrPin = new_ldrPin;
    threshold = new_threshold;
    pinMode(ledPin,OUTPUT);
  }

  //Konstruktor für's LDR-Ausprobieren
  ReflexSensor(int new_ldrPin){  //es reicht, den LDR-Pin anzugeben
    ldrPin = new_ldrPin;
  }
  
  void waitForCan(){
    //Schleife => wartet !!! auf Becher
    do{
      digitalWrite(ledPin,HIGH);  //LED einschalten
      delay(10);
      ledOn=analogRead(ldrPin);    //Hellwert messen
      digitalWrite(ledPin,LOW);   //LED ausschalten
      delay(10);
      ledOff=analogRead(ldrPin);   //Dunkelwert messen
    }while((ledOff-ledOn)<threshold); //solange Differenz
            // der Messwerte unterhalb der Schwelle liegt
  }

  bool detectCan(){
    //wartet nicht; gibt HIGH zurück, wenn Becher erkannt
    //  wurde, ansonsten LOW
    digitalWrite(ledPin,HIGH);  //LED einschalten
    delay(10);
    ledOn=analogRead(ldrPin);    //Hellwert messen
    digitalWrite(ledPin,LOW);   //LED ausschalten
    delay(10);
    ledOff=analogRead(ldrPin);   //Dunkelwert messen
    return((ledOff-ledOn)>=threshold); //     
  }
  
  void showValues(){         //Übertragung schalten
    // - - - - - - - - - - - - - - - - - - - - - - - - -
    // Die Messwerte werden nur zum Einrichten benötigt.
    // bitte Seriellen Plotter starten!  <<<   <<<   <<<
    // - - - - - - - - - - - - - - - - - - - - - - - - -
    Serial.begin(9600);         //Serielle Übertragung einschalten
    Serial.println("LED_on LED_off delta");   //Plot beschriften
    threshold = -20;              //Schleifenabbruch erzwingen
    while(true){                //zum Einrichten nur messen
      waitForCan();
      Serial.print(ledOn);      //Hellwert, ...
      Serial.print(" ");        //Trennzeichen, ...
      Serial.print(ledOff);     //Dunkelwert, ...
      Serial.print(" ");        //Trennzeichen und ...
      Serial.println(ledOff-ledOn); //Differenzwert senden
    }
  }

  void showLDR(){
    // - - - - - - - - - - - - - - - - - - - - - - - - -
    // LDR-Messwert wird nur zum Ausprobieren angezeigt.
    // bitte Seriellen Plotter starten!  <<<   <<<   <<<
    // - - - - - - - - - - - - - - - - - - - - - - - - -
    Serial.begin(9600);         //Serielle Übertragung einschalten
    Serial.println("LDR-Test ");   //Plot beschriften
    while(true){                //zum Ausprobieren nur messen
      Serial.println(analogRead(ldrPin)); //Messwert senden
      delay(50);
    }

  }
};                  //Semikolon am Klassenende nicht vergessen

tumlab.h

# Wokwi Library List
# See https://docs.wokwi.com/guides/libraries

# Automatically added based on includes:
Servo
# ---
