/*********
  Control Led por MQTT 
*********/

#include <WiFi.h>
#include <PubSubClient.h>
#include "DHT.h"


// Replace the next variables with your SSID/Password combination
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Add your MQTT Broker IP address, example:
//const char* mqtt_server = "192.168.1.144";

const char* mqtt_server = "www.ubenga.es";
const char* mqtt_user = "";
const char* mqtt_password = "";
const char* mqtt_topic = "temperatura";
const char* mqtt_topic1 = "humedad";
const char* mqtt_suscripcion = "led";
const int mqtt_port = 1883;

// DHT22 sensor pin
#define DHTPIN 4
// DHT sensor type
#define DHTTYPE DHT22

// Initialize DHT sensor.
DHT dht(DHTPIN, DHTTYPE);

WiFiClient espClient;
PubSubClient client(espClient);
long lastMsg = 0;

// LED Pin
const int ledPin = 5;


void setup() {
  Serial.begin(115200);
  dht.begin();
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  pinMode(ledPin, OUTPUT);
}

void setup_wifi() {
  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  String messageTemp;
  
  for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    messageTemp += (char)message[i];
  }
  Serial.println();

  
  if (String(topic) == "led") {
    Serial.print("Changing output to ");
    if(messageTemp == "on"){
      Serial.println("on");
      digitalWrite(ledPin, HIGH);
    }
    else if(messageTemp == "off"){
      Serial.println("off");
      digitalWrite(ledPin, LOW);
    }
  }
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Creamos un cliente ID para identificarlo en el broker
    String clientId = "Fablab_";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str(), mqtt_user, mqtt_password)) {
      Serial.println("connected");
      // Subscribe
      client.subscribe(mqtt_suscripcion);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  long now = millis();
  if (now - lastMsg > 5000) {
    lastMsg = now;
  
  // Read temperature and humidity from DHT sensor
  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();
  // Publish the sensor data to MQTT broker
  String message = String(temperature) ;
  //String message = String(temperature) + " " + String(humidity);
  client.publish(mqtt_topic, message.c_str());
  String message1 = String(humidity) ;
  client.publish(mqtt_topic1, message1.c_str());
  // Print the sensor data to Serial Monitor
  Serial.print("Temperatura: ");
  Serial.print(temperature);
  Serial.print(" *C ");
  Serial.print("Humedad: ");
  Serial.print(humidity);
  Serial.println(" %");
  // Wait for 2 seconds before publishing next sensor data
  //delay(1000);  
   
  //}
  }
}