#include <LiquidCrystal_I2C.h>
#include <Wire.h>
#include <WiFi.h>
#include <PubSubClient.h>

const char* mqtt_server = "test.mosquitto.org";
const char* ssid = "POANG";
const char* password = "";

WiFiClient espClient;
PubSubClient client(espClient);
LiquidCrystal_I2C lcd(0x27, 16, 2); 

#define pushButtonPin  18
unsigned long lastMsg = 0;
float temperature = 0;

void callback(char* topic, byte* payload, unsigned int length) { //perintah untuk menampilkan data ketika esp32 di setting sebagai subscriber
  String printPayload;
  for (int i = 0; i < length; i++) { //mengecek jumlah data yang ada di topik mqtt
    printPayload+=(char)payload[i];
  }
  lcd.clear();
  Serial.println(printPayload);
  lcd.setCursor(0, 0);
  lcd.print("Suhu ");
  lcd.setCursor(10, 0);
  lcd.print(printPayload);

}

void reconnect() { //perintah koneksi esp32 ke mqtt broker baik itu sebagai publusher atau subscriber
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // perintah membuat client id agar mqtt broker mengenali board yang kita gunakan
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      // Once connected, publish an announcement...
      int action = digitalRead(pushButtonPin);
      if (!action){
        client.publish("/nisa/ledState", "ON"); //publish data dari varibel temp ke broker mqtt
      }else{
          client.publish("/nisa/ledState", "OFF");
      }
      // ... and resubscribe
      client.subscribe("/indobot/p/temp"); //perintah subscribe data ke mqtt broker
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void setup_wifi() { //perintah koneksi wifi
  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA); //setting wifi chip sebagai station/client
  WiFi.begin(ssid, password); //koneksi ke jaringan wifi

  while (WiFi.status() != WL_CONNECTED) { //perintah tunggu esp32 sampi terkoneksi ke wifi
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}


void setup() {
  pinMode(pushButtonPin, INPUT_PULLUP);
  lcd.init();
  Serial.begin(115200);
  setup_wifi(); //memanggil void setup_wifi untuk dieksekusi
  client.setServer(mqtt_server, 1883); //perintah connecting / koneksi awal ke broker
  client.setCallback(callback);
}

void loop() {
    if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 500) { //perintah publish data
    lastMsg = now;
    int action = digitalRead(pushButtonPin);
    if (!action){
        Serial.println("pushed");
        lcd.setCursor(0, 1);
        lcd.print("BUTTON ON");
        lcd.setCursor(10, 1);
        lcd.print(" ");
        client.publish("/nisa/ledState", "ON"); //publish data dari varibel temp ke broker mqtt
    }else{
        Serial.println("no pushed");
        lcd.setCursor(0, 1);
        lcd.print("BUTTON OFF");
        client.publish("/nisa/ledState", "OFF");
    }
  }

}