#define KEY_PIN 20
#define LED_PIN 14
#define WAR_PIN 39
SemaphoreHandle_t led = NULL;         // 二进制信号量
volatile TickType_t keyDeounce = 0;   // 按下按钮的时间
TimerHandle_t timer = NULL;           // 定时器句柄

// 定时器回调函数
void vTimerCallback( TimerHandle_t xTimer ){
  digitalWrite(LED_PIN, !digitalRead(LED_PIN));
}

void led_task(void *param_t){
  pinMode(LED_PIN, OUTPUT);
  pinMode(WAR_PIN, OUTPUT);
  while(1){
    // 这种去抖方式是很Low的，正确的方式要使用定时器。
    if((xSemaphoreTake(led, 1000) == pdTRUE) && ((xTaskGetTickCount() - keyDeounce) < 200)){
      // 创建定时器并启动他
      if(timer == NULL){
        timer = xTimerCreate("Timer_LED",       // 定时器的名字
                              2000,             // 调用间隔时间
                              pdFALSE,          // 只运行一次
                              NULL,             // 定时器标识符，相当于参数
                              vTimerCallback);
      }
      if(xTimerIsTimerActive(timer) == pdFALSE){
        xTimerStart(timer,0);
        // printf("按了开关...\n");
      }else{
        // printf("迷瞪中...\n");
        digitalWrite(WAR_PIN, !digitalRead(WAR_PIN));
      }
      vTaskDelay(500);
    }
  }
}

// 中断服务函数
void IRAM_ATTR ISR() {
  keyDeounce = xTaskGetTickCountFromISR();    // 记录下按下的时间，用于放抖动，正式开发中不要这样写，有Bug
  xSemaphoreGiveFromISR(led, NULL);
}

void setup() {
  Serial.begin(115200);
  led = xSemaphoreCreateBinary();           //创建二进制信号量
  xTaskCreate(led_task, "LED-DSP", 1024, NULL, 1, NULL);
  // 安装中断
  pinMode(KEY_PIN, INPUT_PULLUP);
  attachInterrupt(KEY_PIN, ISR, FALLING);
}

void loop() {
  delay(10);
}