#include <ESP8266WiFi.h>
#include <Firebase_ESP_Client.h>
#include <DHT.h>

//Untuk token generation dan process info.
#include <addons/TokenHelper.h>

#define DHTpin D2
#define DHTtype DHT11

DHT dht(DHTpin, DHTtype);

float suhu = 0;
int kelembaban = 0;

/* 1. Masukkan Wifi dan Password */
#define WIFI_SSID "YOUR-WIFI"
#define WIFI_PASSWORD "YOUR-PASS"

/* 2. Masukkan API Key */
#define API_KEY "YOUR API KEY"

/* 3.Masukkan project ID */
#define FIREBASE_PROJECT_ID "YOUR PROJECT ID"

/* 4. Masukkan email dan password yang terdaftar dalam proyek */
#define USER_EMAIL "YOUR-FIREBASE-EMAIL"
#define USER_PASSWORD "YOUR-FIREBASE-PASS"

//Firebase Data object
FirebaseData fbdo;

FirebaseAuth auth;
FirebaseConfig config;

unsigned long dataMillis = 0;
int count = 0;

//The Firestore payload upload callback function
void fcsUploadCallback(CFS_UploadStatusInfo info)
{
    if (info.status == fb_esp_cfs_upload_status_init)
    {
        Serial.printf("\nUploading data (%d)...\n", info.size);
    }
    else if (info.status == fb_esp_cfs_upload_status_upload)
    {
        Serial.printf("Uploaded %d%s\n", (int)info.progress, "%");
    }
    else if (info.status == fb_esp_cfs_upload_status_complete)
    {
        Serial.println("Upload completed ");
    }
    else if (info.status == fb_esp_cfs_upload_status_process_response)
    {
        Serial.print("Processing the response... ");
    }
    else if (info.status == fb_esp_cfs_upload_status_error)
    {
        Serial.printf("Upload failed, %s\n", info.errorMsg.c_str());
    }
}

void readDHT11(){
  suhu = dht.readTemperature();
  kelembaban = dht.readHumidity();
  Serial.print("Suhu: ");
  Serial.println(suhu);
  Serial.print("Kelembaban: ");
  Serial.println(kelembaban);
}

void setup()
{
    Serial.begin(115200);
    delay(500);
    dht.begin();
    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    Serial.print("Connecting to Wi-Fi");
    while (WiFi.status() != WL_CONNECTED)
    {
        Serial.print(".");
        delay(300);
    }
    Serial.println();
    Serial.print("Connected with IP: ");
    Serial.println(WiFi.localIP());
    Serial.println();

    Serial.printf("Firebase Client v%s\n\n", FIREBASE_CLIENT_VERSION);

    config.api_key = API_KEY;
    auth.user.email = USER_EMAIL;
    auth.user.password = USER_PASSWORD;

    /* Assign the callback function for the long running token generation task */
    config.token_status_callback = tokenStatusCallback; //see addons/TokenHelper.h

    Firebase.begin(&config, &auth);

    Firebase.reconnectWiFi(true);

}

void loop()
{
    //pembacaan data DHT11
    readDHT11();
    
    // Pengiriman data 1 menit sekali
    if (Firebase.ready() && (millis() - dataMillis > 60000 || dataMillis == 0))
    {
        dataMillis = millis();
        FirebaseJson content;

        String documentPath = "data/a" + String(count);

        String doc_path = "projects/";
        doc_path += FIREBASE_PROJECT_ID;
        doc_path += "/databases/(default)/documents/coll_id/doc_id"; //coll_id and doc_id are your collection id and document id

        //data suhu dan kelembaban
        content.set("fields/DHT11/arrayValue/values/[0]/stringValue", "temperature");
        content.set("fields/DHT11/arrayValue/values/[1]/integerValue", suhu);
        content.set("fields/DHT11/arrayValue/values/[2]/stringValue", "humidity");
        content.set("fields/DHT11/arrayValue/values/[3]/integerValue", kelembaban);

        //data lokasi maps
        content.set("fields/Maps/geoPointValue/latitude", -7.772671);
        content.set("fields/Maps/geoPointValue/longitude", 110.386958);

        count++;

        Serial.print("Create a document... ");

        if (Firebase.Firestore.createDocument(&fbdo, FIREBASE_PROJECT_ID, "" /* databaseId can be (default) or empty */, documentPath.c_str(), content.raw()))
            Serial.printf("ok\n%s\n\n", fbdo.payload().c_str());
        else
            Serial.println(fbdo.errorReason());
    }
}