/**************************************************************************

  This is an Arduino code that uses the Adafruit_NeoPixel library to control a strip of 
  NeoPixel LEDs. NeoPixels are individually addressable RGB LEDs that can be programmed
   to display various colors and patterns.

  Here's a breakdown of the code:

  1. The code includes the necessary libraries, including the Adafruit_NeoPixel library
   for controlling the NeoPixel strip.

  2. The `PIN` constant is defined to specify the Arduino pin number to which the NeoPixel
   strip is connected.

  3. An instance of the Adafruit_NeoPixel class called `strip` is created with the parameters:
   the number of pixels in the strip (60), the pin number, and the pixel type flags
    (NEO_GRB and NEO_KHZ800). These flags indicate that the pixels are wired for GRB
     bitstream and operate at 800 KHz.

  4. The `setup()` function is called once at the beginning of the program. 
  It initializes the NeoPixel strip, sets the brightness to 50, and turns off
   all the pixels.

  5. The `loop()` function is called repeatedly in a loop. It demonstrates some example
   procedures to display different colors and patterns on the NeoPixel strip.

  6. The `colorWipe()` function is a procedure that fills the pixels one after the 
  other with a specified color. It takes a color value (`c`) and a delay time (`wait`) as parameters.

  7. The `rainbow()` function displays a smoothly transitioning rainbow effect on the
   NeoPixel strip. It takes a delay time (`wait`) as a parameter.

  8. The `rainbowCycle()` function displays a rainbow effect that cycles through all 
  the colors equally distributed throughout the strip. It takes a delay time (`wait`) as a parameter.

  9. The `theaterChase()` function creates a theater-style crawling lights effect. 
  It takes a color value (`c`) and a delay time (`wait`) as parameters.

  10. The `theaterChaseRainbow()` function creates a theater-style crawling lights 
  effect with a rainbow effect. It takes a delay time (`wait`) as a parameter.

  11. The `Wheel()` function is a utility function that maps a value from 0 to 
  255 to a color value on the RGB color wheel. It returns a 32-bit color value based
  on the input value.

  The code can be uploaded to an Arduino board with a connected NeoPixel strip to
   control the LEDs and create different lighting effects. Make sure to wire the 
   NeoPixel strip correctly and follow any additional precautions mentioned in 
   the code comments to avoid damaging the LEDs.


by arvind patil 1/05/23



















********************************************************************/

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
#include <avr/power.h>
#endif

#define PIN 6

// Parameter 1 = number of pixels in strip
// Parameter 2 = Arduino pin number (most are valid)
// Parameter 3 = pixel type flags, add together as needed:
//   NEO_KHZ800  800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
//   NEO_KHZ400  400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
//   NEO_GRB     Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB     Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
//   NEO_RGBW    Pixels are wired for RGBW bitstream (NeoPixel RGBW products)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(60, PIN, NEO_GRB + NEO_KHZ800);

// IMPORTANT: To reduce NeoPixel burnout risk, add 1000 uF capacitor across
// pixel power leads, add 300 - 500 Ohm resistor on first pixel's data input
// and minimize distance between Arduino and first pixel.  Avoid connecting
// on a live circuit...if you must, connect GND first.

void setup() {
  // This is for Trinket 5V 16MHz, you can remove these three lines if you are not using a Trinket
#if defined (__AVR_ATtiny85__)
  if (F_CPU == 16000000) clock_prescale_set(clock_div_1);
#endif
  // End of trinket special code

  strip.begin();
  strip.setBrightness(50);
  strip.show(); // Initialize all pixels to 'off'
}

void loop() {
  // Some example procedures showing how to display to the pixels:
  colorWipe(strip.Color(255, 0, 0), 50); // Red
  colorWipe(strip.Color(0, 255, 0), 50); // Green
  colorWipe(strip.Color(0, 0, 255), 50); // Blue
  //colorWipe(strip.Color(0, 0, 0, 255), 50); // White RGBW
  // Send a theater pixel chase in...
  theaterChase(strip.Color(127, 127, 127), 50); // White
  theaterChase(strip.Color(127, 0, 0), 50); // Red
  theaterChase(strip.Color(0, 0, 127), 50); // Blue

  rainbow(20);
  rainbowCycle(20);
  theaterChaseRainbow(50);
}

// Fill the dots one after the other with a color
void colorWipe(uint32_t c, uint8_t wait) {
  for (uint16_t i = 0; i < strip.numPixels(); i++) {
    strip.setPixelColor(i, c);
    strip.show();
    delay(wait);
  }
}

void rainbow(uint8_t wait) {
  uint16_t i, j;

  for (j = 0; j < 256; j++) {
    for (i = 0; i < strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel((i + j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

// Slightly different, this makes the rainbow equally distributed throughout
void rainbowCycle(uint8_t wait) {
  uint16_t i, j;

  for (j = 0; j < 256 * 5; j++) { // 5 cycles of all colors on wheel
    for (i = 0; i < strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

//Theatre-style crawling lights.
void theaterChase(uint32_t c, uint8_t wait) {
  for (int j = 0; j < 10; j++) { //do 10 cycles of chasing
    for (int q = 0; q < 3; q++) {
      for (uint16_t i = 0; i < strip.numPixels(); i = i + 3) {
        strip.setPixelColor(i + q, c);  //turn every third pixel on
      }
      strip.show();

      delay(wait);

      for (uint16_t i = 0; i < strip.numPixels(); i = i + 3) {
        strip.setPixelColor(i + q, 0);      //turn every third pixel off
      }
    }
  }
}

//Theatre-style crawling lights with rainbow effect
void theaterChaseRainbow(uint8_t wait) {
  for (int j = 0; j < 256; j++) {   // cycle all 256 colors in the wheel
    for (int q = 0; q < 3; q++) {
      for (uint16_t i = 0; i < strip.numPixels(); i = i + 3) {
        strip.setPixelColor(i + q, Wheel( (i + j) % 255)); //turn every third pixel on
      }
      strip.show();

      delay(wait);

      for (uint16_t i = 0; i < strip.numPixels(); i = i + 3) {
        strip.setPixelColor(i + q, 0);      //turn every third pixel off
      }
    }
  }
}

// Input a value 0 to 255 to get a color value.
// The colours are a transition r - g - b - back to r.
uint32_t Wheel(byte WheelPos) {
  WheelPos = 255 - WheelPos;
  if (WheelPos < 85) {
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  if (WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
  WheelPos -= 170;
  return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}