#include <Arduino.h>
#include "LED.h"

LED leds[] {
  {18, 250},
  {19, 500},
  {21, 750}
};

void setup() {
}

void loop() {
  for (auto& led : leds) led.blink();
  
  delay(10);
}


sketch.ino

diagram.json

#include <Arduino.h>

class LED {
  public:
    LED(int gpio, unsigned long blinkDelay = 0, bool inverted = false);
    ~LED();
    void setState(bool newState);
    void toggle();
    void turnOn();
    void turnOff();
    void blink();
  protected:
    int gpio;
    bool inverted;
    bool state;

    unsigned long blinkDelay;
    unsigned long lastMillis;
};

LED.h

#include "LED.h"

LED::LED(int gpio, unsigned long blinkDelay, bool inverted) 
: gpio(gpio)
, inverted(inverted) 
, blinkDelay(blinkDelay) {
  pinMode(gpio, OUTPUT);
  turnOff();
};

LED::~LED() {
  turnOff();
}

void LED::setState(bool newState) {
  state = newState;
  digitalWrite(gpio, inverted ? !state : state);
}

void LED::toggle() {
  bool newState = !state;
  setState(newState);
}

void LED::turnOn() {
  setState(true);
}

void LED::turnOff() {
  setState(false);
}

void LED::blink() {
  if (!blinkDelay) return;

  unsigned long currentMillis = millis();
  if (lastMillis && currentMillis - lastMillis < blinkDelay) return;

  lastMillis = currentMillis;
  toggle();
}