/**
   Arduino Electronic Safe v2
   by SebraZor 2023
   Copyright (C) 2020, Uri Shaked.
   Released under the MIT License.
*/

#include <LiquidCrystal.h>
#include <Keypad.h>
#include <Servo.h>
#include "SafeState.h"
#include "icons.h"

/* Locking mechanism definitions */
#define LED1 13
#define SERVO_PIN 6
#define SERVO_LOCK_POS   20
#define SERVO_UNLOCK_POS 90
Servo lockServo;

/* Display */
LiquidCrystal lcd(12, 11, 10, 9, 8, 7);

/* Keypad setup */
const byte KEYPAD_ROWS = 4;
const byte KEYPAD_COLS = 4;
byte rowPins[KEYPAD_ROWS] = {5, 4, 3, 2};
byte colPins[KEYPAD_COLS] = {A3, A2, A1, A0};
char keys[KEYPAD_ROWS][KEYPAD_COLS] = {
  {'1', '2', '3', 'A'},
  {'4', '5', '6', 'B'},
  {'7', '8', '9', 'C'},
  {'*', '0', '#', 'D'}
};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, KEYPAD_ROWS, KEYPAD_COLS);

/* SafeState stores the secret code in EEPROM */
SafeState safeState;

void lock() {
  lockServo.write(SERVO_LOCK_POS);
  safeState.lock();
  digitalWrite(LED1, 1);
}

void unlock() {
  lockServo.write(SERVO_UNLOCK_POS);
  digitalWrite(LED1, LOW);
}

void showStartupMessage() {
  lcdPrintMessage(2,0,"Welcome !");
  delay(1000);
  digitalWrite(LED1, 1);
  lcdScrollMessage(0,2,"ArduinoSafe v2.0");
  delay(500);
  digitalWrite(LED1, LOW);
    delay(500);
  digitalWrite(LED1, 1);
  delay(500);
  digitalWrite(LED1, LOW);
  delay(500);
  digitalWrite(LED1, 1);
  delay(500);
  digitalWrite(LED1, LOW);
}

void lcdPrintMessage(int line, int col, String message) {
  lcd.setCursor(line, col);
  lcd.print(message);
}

void lcdWriteChar(int line, int col, char car) {
  lcd.setCursor(line, col);
  lcd.write(car);
}

void lcdScrollMessage(int line, int col, String message) {
  lcd.setCursor(line, col);
  for (byte i = 0; i < message.length(); i++) {
    lcd.print(message[i]);
    delay(100);
  }
}

String inputSecretCode() {
  lcdPrintMessage(5,1,"[____]");

  lcd.setCursor(6, 1);
  String result = "";
  while (result.length() < 4) {
    char key = keypad.getKey();
    if (key >= '0' && key <= '9') {
      lcd.print('*');
      result += key;
    }
  }
  return result;
}

void showWaitScreen(int delayMillis) {
  lcdPrintMessage(2,1,"[..........]");

  lcd.setCursor(3, 1);
  for (byte i = 0; i < 10; i++) {
    delay(delayMillis);
    lcd.print("=");
  }
}

bool setNewCode() {
  lcd.clear();
  lcdPrintMessage(0,0,"Enter new code:");
  String newCode = inputSecretCode();

  lcd.clear();
  lcdPrintMessage(0,0,"Confirm new code:");
  String confirmCode = inputSecretCode();

  if (newCode.equals(confirmCode)) {
    safeState.setCode(newCode);
    return true;
  } else {
    lcd.clear();
    lcdPrintMessage(1,0,"Code mismatch");
    lcdPrintMessage(0,1,"Safe not locked!");
    delay(2000);
    return false;
  }
}

void showUnlockMessage() {
  lcd.clear();
  lcdWriteChar(0,0,ICON_UNLOCKED_CHAR);
  lcdPrintMessage(4,0,"Unlocked!");
  lcdWriteChar(15,0,ICON_UNLOCKED_CHAR);
  delay(1000);
}

void safeUnlockedLogic() {
  lcd.clear();
  lcdWriteChar(0,0,ICON_UNLOCKED_CHAR);
  lcdPrintMessage(3,0,"# to lock");
  lcdWriteChar(15,0,ICON_UNLOCKED_CHAR);

  bool newCodeNeeded = true;
  if (safeState.hasCode()) {
    lcdPrintMessage(0,3,"A=new code");
    newCodeNeeded = false;
  }

  auto key = keypad.getKey();
  while (key != 'A' && key != '#') {
    key = keypad.getKey();
  }

  bool readyToLock = true;
  if (key == 'A' || newCodeNeeded) {
    readyToLock = setNewCode();
  }

  if (readyToLock) {
    lcd.clear();
    lcdWriteChar(5,0,ICON_UNLOCKED_CHAR);
    lcdWriteChar(7,0,ICON_RIGHT_ARROW);
    lcdWriteChar(9,0,ICON_LOCKED_CHAR);
    safeState.lock();
    lock();
    showWaitScreen(100);
  }
}

void safeLockedLogic() {
  lcd.clear();
  lcdWriteChar(0,0,ICON_LOCKED_CHAR);
  lcdPrintMessage(2,0,"Safe Locked!");
  lcdWriteChar(15,0,ICON_LOCKED_CHAR);

  String userCode = inputSecretCode();
  bool unlockedSuccessfully = safeState.unlock(userCode);
  showWaitScreen(200);

  if (unlockedSuccessfully) {
    showUnlockMessage();
    unlock();
  } else {
    lcd.clear();
    lcdPrintMessage(0,0,"Access Denied!");
    showWaitScreen(1000);
  }
}

void setup() {
  lcd.begin(16, 2);
  init_icons(lcd);

  lockServo.attach(SERVO_PIN);

  pinMode(LED1, OUTPUT);

  /* Make sure the physical lock is sync with the EEPROM state */
  Serial.begin(115200);
  if (safeState.locked()) {
    lock();
  } else {
    unlock();
  }

  showStartupMessage();
}

void loop() {
  if (safeState.locked()) {
    safeLockedLogic();
  } else {
    safeUnlockedLogic();
  }
}