//按A键设置新密码，按#号键锁定密码箱
//按A键设置新密码，按#号键锁定密码箱
//按A键设置新密码，按#号键锁定密码箱

#include <LiquidCrystal.h>
#include <LiquidCrystal.h>  // 引入 LiquidCrystal 库，用于控制 LCD 显示器
#include <Keypad.h>         // 引入 Keypad 库，用于操作键盘
#include <Servo.h>          // 引入 Servo 库，用于控制舵机
#include "SafeState.h"      // 引入 SafeState 库，用于管理保险箱状态
#include "icons.h"          // 引入 icons 库，用于显示图标字符

#define LED_R A4   // 红色 LED 灯引脚
#define LED_G A5   // 绿色 LED 灯引脚

/* 锁定机制定义 */
#define SERVO_PIN 6           // 舵机引脚
#define SERVO_LOCK_POS   20    // 舵机锁定位置
#define SERVO_UNLOCK_POS 90    // 舵机解锁位置
Servo lockServo;              // 定义舵机对象

/* 显示 */
LiquidCrystal lcd(12, 11, 10, 9, 8, 7);  // 创建 LiquidCrystal 对象，用于控制 LCD 显示器

/* 键盘设置 */
const byte KEYPAD_ROWS = 4;
const byte KEYPAD_COLS = 4;
byte rowPins[KEYPAD_ROWS] = {5, 4, 3, 2};   // 设置键盘行引脚
byte colPins[KEYPAD_COLS] = {A3, A2, A1, A0};  // 设置键盘列引脚
char keys[KEYPAD_ROWS][KEYPAD_COLS] = {
  {'1', '2', '3', 'A'},
  {'4', '5', '6', 'B'},
  {'7', '8', '9', 'C'},
  {'*', '0', '#', 'D'}
};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, KEYPAD_ROWS, KEYPAD_COLS);

/* SafeState 在 EEPROM 存储秘密代码 */
SafeState safeState;

// 锁定操作函数
void lock() {
  lockServo.write(SERVO_LOCK_POS);  // 控制舵机锁定
  safeState.lock();  // 锁定保险箱状态
  digitalWrite(LED_R, HIGH);  // 点亮红色 LED
  digitalWrite(LED_G, LOW);   // 关闭绿色 LED
}

// 解锁操作函数
void unlock() {
  lockServo.write(SERVO_UNLOCK_POS);  // 控制舵机解锁
  digitalWrite(LED_G, HIGH);  // 点亮绿色 LED
  digitalWrite(LED_R, LOW);   // 关闭红色 LED
}

// 显示启动消息
void showStartupMessage() {
  lcd.setCursor(4, 0);
  lcd.print("Welcome!");
  delay(1000);

  lcd.setCursor(0, 2);
  String message = "author: Tianning";
  for (byte i = 0; i < message.length(); i++) {
    lcd.print(message[i]);
    delay(100);
  }
  delay(500);
}

// 输入秘密代码
String inputSecretCode() {
  lcd.setCursor(5, 1);
  lcd.print("[____]");
  lcd.setCursor(6, 1);
  String result = "";
  while (result.length() < 4) {
    char key = keypad.getKey();
    if (key >= '0' && key <= '9') {
      lcd.print('*');
      result += key;
    }
  }
  return result;
}

// 显示等待屏幕
void showWaitScreen(int delayMillis) {
  lcd.setCursor(2, 1);
  lcd.print("[..........]");
  lcd.setCursor(3, 1);
  for (byte i = 0; i < 10; i++) {
    delay(delayMillis);
    lcd.print("=");
  }
}

// 设置新代码函数
bool setNewCode() {
  lcd.clear();  // 清空 LCD 显示
  lcd.setCursor(0, 0);
  lcd.print("Enter new code:");
  String newCode = inputSecretCode();  // 输入新代码

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Confirm new code");
  String confirmCode = inputSecretCode();  // 输入确认代码

  if (newCode.equals(confirmCode)) {
    safeState.setCode(newCode);  // 设置新的保险箱代码
    return true;
  } else {
    lcd.clear();
    lcd.setCursor(1, 0);
    lcd.print("Code mismatch");
    lcd.setCursor(0, 1);
    lcd.print("Safe not locked!");
    delay(2000);
    return false;
  }
}

// 显示解锁消息
void showUnlockMessage() {
  lcd.clear();  // 清空 LCD 显示
  lcd.setCursor(0, 0);
  lcd.write(ICON_UNLOCKED_CHAR);  // 显示解锁图标字符
  lcd.setCursor(4, 0);
  lcd.print("Unlocked!");
  lcd.setCursor(15, 0);
  lcd.write(ICON_UNLOCKED_CHAR);
  delay(1000);
}

// 解锁状态逻辑
void safeUnlockedLogic() {
  lcd.clear();  // 清空 LCD 显示

  lcd.setCursor(0, 0);
  lcd.write(ICON_UNLOCKED_CHAR);  // 显示解锁图标字符
  lcd.setCursor(2, 0);
  lcd.print(" # to lock");
  lcd.setCursor(15, 0);
  lcd.write(ICON_UNLOCKED_CHAR);

  bool newCodeNeeded = true;

  if (safeState.hasCode()) {
    lcd.setCursor(0, 1);
    lcd.print("  A = new code");  //按A键设置新密码，按#号键锁定密码箱
    newCodeNeeded = false;
  }

  auto key = keypad.getKey();
  while (key != 'A' && key != '#') {
    key = keypad.getKey();
  }

  bool readyToLock = true;
  if (key == 'A' || newCodeNeeded) {
    readyToLock = setNewCode();
  }

  if (readyToLock) {
    lcd.clear();  // 清空 LCD 显示
    lcd.setCursor(5, 0);
    lcd.write(ICON_UNLOCKED_CHAR);  // 显示解锁图标字符
    lcd.print(" ");
    lcd.write(ICON_RIGHT_ARROW);
    lcd.print(" ");
    lcd.write(ICON_LOCKED_CHAR);

    safeState.lock();  // 锁定保险箱状态
    lock();  // 执行锁定操作
    showWaitScreen(100);  // 显示等待屏幕
  }
}


// 锁定状态逻辑
void safeLockedLogic() {
  lcd.clear();  // 清空 LCD 显示
  lcd.setCursor(0, 0);
  lcd.write(ICON_LOCKED_CHAR);  // 显示锁定图标字符
  lcd.print(" Safe Locked! ");
  lcd.write(ICON_LOCKED_CHAR);

  String userCode = inputSecretCode();  // 输入用户代码
  bool unlockedSuccessfully = safeState.unlock(userCode);  // 尝试解锁
  showWaitScreen(200);  // 显示等待屏幕

  if (unlockedSuccessfully) {
    showUnlockMessage();  // 显示解锁消息
    unlock();  // 执行解锁操作
  } else {
    lcd.clear();  // 清空 LCD 显示
    lcd.setCursor(0, 0);
    lcd.print("Access Denied!");
    showWaitScreen(1000);  // 显示等待屏幕
  }
}

void setup() {
  pinMode(LED_R, OUTPUT);
  pinMode(LED_G, OUTPUT);
  lcd.begin(16, 2);  // 初始化 LCD 显示
  init_icons(lcd);  // 初始化图标

  lockServo.attach(SERVO_PIN);  // 绑定舵机引脚

  /* 确保物理锁与 EEPROM 状态同步 */
  Serial.begin(115200);  // 启动串口通信
  if (safeState.locked()) {
    lock();  // 锁定保险箱状态
  } else {
    unlock();  // 解锁保险箱状态
  }

  showStartupMessage();  // 显示启动消息
}

void loop() {
  if (safeState.locked()) {
    safeLockedLogic();  // 执行锁定状态逻辑
  } else {
    safeUnlockedLogic();  // 执行解锁状态逻辑
  }
}