// Tutorial de uso do Franzininho:
// https://embarcados.com.br/serie/franzininho-wifi-arduino/

#include <TM1637Display.h>

#define SCL 9
#define SDA 8

// Declara o objeto TM1637Display
TM1637Display display(SCL, SDA, DEFAULT_BIT_DELAY);

// Define o padrão para exibir o retângulo
const uint8_t ret[] =
{
  SEG_A|SEG_F|SEG_E|SEG_D,
  SEG_A|SEG_D,
  SEG_A|SEG_D,
  SEG_A|SEG_B|SEG_C|SEG_D
};

const uint8_t one_seg[] = { SEG_G };
const uint8_t turn_off_one_seg[] = { 0x00 };

// Função que realiza uma animação no display
void animation()
{
  int i;
 
  // Animação de ida
  for (i = 0; i < 4; i++)
  {
    display.setSegments(one_seg, 1, i); // Mostra o segmento no índice i
    delay(500);
    display.setSegments(turn_off_one_seg, 1, i); // Desliga o segmento no índice i
  }
 
  // Animação de volta
  for (i = 3; i >= 0; i--)
  {
    display.setSegments(one_seg, 1, i);
    delay(500);
    display.setSegments(turn_off_one_seg, 1, i);
  }
}

void setup()
{
  // Inicializa a comunicação serial na velocidade de 115200 bps
  Serial.begin(115200);
 
  // Define a intensidade luminosa do display (0-7)
  display.setBrightness(5);
 
  // Limpa o display
  display.clear();

  // Formato para mostrar hora e minuto (14:15)
  int time_in_display = (14 * 100) + 15;
  display.showNumberDecEx(time_in_display, 0b11100000, true);
  delay(1500);
  display.clear();
 
  // Cria um retângulo no display
  display.setSegments(ret, 4, 0);
  delay(1500);
  display.clear();

  // Mostra o número -10 no display
  display.showNumberDec(-10);  
  delay(1500);
  display.clear();
 
  // Mostra o número 15 no display (com o sinal de menos)
  display.showNumberDec(15, true);
  delay(1500);
  display.clear();
 
  // Mostra o número 20 no display (sem o sinal de menos) com dois dígitos (20)
  display.showNumberDec(20, false, 2, 1);
  delay(2000);
  display.clear();
}

void loop()
{
  // Executa a animação
  animation();
}