#include <LiquidCrystal_I2C.h>
#include <Keypad.h>

LiquidCrystal_I2C lcd(0x27, 16, 2); 

const byte ROWS = 4; 
const byte COLS = 4; 

char keys[ROWS][COLS] = {
  {'1','2','3','+'},
  {'4','5','6','-'},
  {'7','8','9','*'},
  {'C', '0','=','/'}};

byte rowPins[ROWS] = {5, 4, 3, 2};
byte colPins[COLS] = {A3, A2, A1, A0};

Keypad keypad = Keypad( makeKeymap(keys), rowPins, colPins, ROWS, COLS );

String inputString = "";

void messageScreen() {
  lcd.print("     A-B-C's");
  lcd.setCursor(3, 1);
  String message = "Calculator";
  for (byte i = 0; i < message.length(); i++) {
    lcd.print(message[i]);
    delay(50);
  }
  delay(500);
}

void updateCursor() {
  if (millis() / 250 % 2 == 0 ) {
    lcd.cursor();
  } else {
    lcd.noCursor();
  }
}

char operation = 0;
String memory = "";
String current = "";

int calculate(char operation, int left, int right) {
  switch (operation) {
    case '+': 
    return left + right;

    case '-': 
    return left - right;

    case '*': 
    return left * right;

    case '/': 
    return left / right;
  }
  return 0; // Default case, should not happen if the input is correct
}

void inputs(char buttn) {

  if ('C' == buttn) {
    // Clear the input when 'C' is pressed
    current = "";
    memory = "";
    operation = 0;
    lcd.clear();
    lcd.setCursor(1, 0);
  } 
  
  else if ('-' == buttn && current == "") {
    current = "-";
    lcd.print("-");
    
  } 
  
  else if (buttn == '+' || buttn == '-' || buttn == '*' || buttn == '/') {

    if (current != "") {
      if (memory == "") {
        memory = current;
        current = "";
      } 
      
      else {
        int leftNum = memory.toInt();
        int rightNum = current.toInt();
        memory = String(calculate(operation, leftNum, rightNum));
        current = "";
        lcd.clear();
        lcd.setCursor(1, 0);
        lcd.print(memory);

      }
    }
    operation = buttn;
    lcd.setCursor(0, 1);
    lcd.print(buttn);
    lcd.setCursor(current.length() + 1, 1);
  } 
  
  else if (buttn == '=') {
    if (current != "" && memory != "" && operation != 0) {
      int leftNum = memory.toInt();
      int rightNum = current.toInt();
      memory = String(calculate(operation, leftNum, rightNum));
      lcd.clear();
      lcd.setCursor(1, 0);
      lcd.print(memory);
      lcd.setCursor(0, 1);
      current = "";
    }
  } 
  
  else if (buttn == '.') {
    if (current.length() > 0) {
      current.remove(current.length() - 1);
      lcd.clear();
      lcd.setCursor(1, 0);
      lcd.print(current);
    }
  } 
  
  else {
    current += buttn;
    lcd.print(buttn);
  }
}

void setup(){
  Serial.begin(115200);
  lcd.begin(16, 2);
  messageScreen();
  lcd.clear();
  lcd.cursor();
  lcd.setCursor(1, 0);
}

void loop() {
  updateCursor();

  char buttn = keypad.getKey();
  if (buttn) {
    inputs(buttn);
  }
}