#include <WiFi.h>
#include <PubSubClient.h>
// #include <Adafruit_Sensor.h>
#include <DHT.h>

#define DHTPIN 2         // Pin connected to the DHT22 sensor
#define LEDPIN 4         // Pin connected to the LED

#define WIFI_SSID "Wokwi-GUEST"
#define WIFI_PASSWORD ""
#define MQTT_SERVER "196.112.125.31"
#define MQTT_PORT 1883
#define MQTT_CLIENT_ID "esp32_client"
#define MQTT_TOPIC_TEMPERATURE "temperature"
#define MQTT_TOPIC_HUMIDITY "humidity"
#define MQTT_TOPIC_LED "lamp"

#define DHTTYPE DHT22     // DHT sensor type

DHT dht(DHTPIN, DHTTYPE);
WiFiClient espClient;
PubSubClient client(espClient);

void setup() {
  pinMode(LEDPIN, OUTPUT);
  Serial.begin(115200);

  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }

  Serial.println("Connected to WiFi");

  client.setServer(MQTT_SERVER, MQTT_PORT);
  client.setCallback(callback);

  while (!client.connected()) {
    if (client.connect(MQTT_CLIENT_ID)) {
      Serial.println("Connected to MQTT broker");
      client.subscribe(MQTT_TOPIC_LED);
    } else {
      Serial.print("Failed to connect to MQTT broker, rc=");
      Serial.print(client.state());
      Serial.println(" Retrying in 5 seconds...");
      delay(5000);
    }
  }

  dht.begin();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  if (isnan(temperature) || isnan(humidity)) {
    Serial.println("Failed to read data from DHT sensor");
    return;
  }

  client.publish(MQTT_TOPIC_TEMPERATURE, String(temperature).c_str());
  client.publish(MQTT_TOPIC_HUMIDITY, String(humidity).c_str());

  delay(5000);
}

void callback(char* topic, byte* payload, unsigned int length) {
  String receivedTopic = String(topic);
  String message = "";

  for (unsigned int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  Serial.println("Received message: " + message);

  if (receivedTopic.equals(MQTT_TOPIC_LED)) {
    if (message.equals("on")) {
      digitalWrite(LEDPIN, HIGH);
      Serial.println("LED turned on");
    } else if (message.equals("off")) {
      digitalWrite(LEDPIN, LOW);
      Serial.println("LED turned off");
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    if (client.connect(MQTT_CLIENT_ID)) {
      Serial.println("Connected to MQTT broker");
      client.subscribe(MQTT_TOPIC_LED);
    } else {
      Serial.print("Failed to connect to MQTT broker, rc=");
      Serial.print(client.state());
      Serial.println(" Retrying in 5 seconds...");
      delay(5000);
    }
  }
}