#include <WiFi.h>
#include <Wire.h>
#include <Adafruit_SSD1306.h>

Adafruit_SSD1306 display(128, 64, &Wire);

#define NTP_SERVER     "pool.ntp.org"
#define UTC_OFFSET     -7 * 3600 // MST UTC -7 hours
#define UTC_OFFSET_DST 0

void spinner() {
  static int8_t counter = 0;
  const char* glyphs = "|/-\\";
  display.setCursor(120, 50);
  display.print(glyphs[counter++]);
  if (counter == strlen(glyphs)) {
    counter = 0;
  }
  display.display();
}

void printLocalTime() {
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    display.setCursor(0, 30);
    display.println("Connection Err");
    display.display();
    return;
  }

  char buffer[10];
  strftime(buffer, sizeof(buffer), "%I:%M:%S", &timeinfo);
  display.setCursor(0, 0);
  display.println(buffer);

  display.setCursor(0, 10);
  display.println(&timeinfo, "%d/%m/%Y");
  display.display();
}

void setup() {
  Serial.begin(115200);

  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 20);
  display.println("Connecting to WiFi");
  display.display();

  WiFi.begin("Wokwi-GUEST", "", 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(250);
    spinner();
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  display.clearDisplay();
  display.setCursor(0, 20);
  display.println("Online");
  display.setCursor(0, 30);
  display.println("Updating time...");
  display.display();

  configTime(UTC_OFFSET, UTC_OFFSET_DST, NTP_SERVER);
}

void loop() {
  display.clearDisplay();
  printLocalTime();
  delay(250);
}