#include <WiFi.h>
#include <SPI.h>
#include <Wire.h>
//  #include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// SDA 21
// SCL 22

char ssid[] = "Wokwi-GUEST";      // your network SSID (name)
char pass[] = "";                 // your network password

#define NTP_SERVER     "pool.ntp.org"
#define UTC_OFFSET     -5 * 60 * 60
#define UTC_OFFSET_DST  1 * 60 * 60

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
#define SCREEN_ADDRESS 0x3C ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

void setup() {
  Serial.begin(9600);

  if (!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for (;;); // Don't proceed, loop forever
  }

  display.display();            // Adafruit Logo
  delay(1000);
  display.clearDisplay();

  WiFi.begin(ssid, pass, 6);

  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);
  display.println("Connecting to");
  display.println(ssid);
  display.display();

  while (WiFi.status() != WL_CONNECTED) {
    delay(250);
    display.print("* ");
    display.display();
  }
  // delay(500);

  configTime(UTC_OFFSET, UTC_OFFSET_DST, NTP_SERVER);

  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);
  display.drawRect(0, 0, display.width(), display.height(), SSD1306_WHITE);
}

void loop() {
  displayTime();
  display.display();
  delay(1000);
}

void displayTime() {
  display.fillRect(10, 10, 108, 20, SSD1306_BLACK);   // clear time
  display.setTextSize(2);
  display.setCursor(15, 13);

  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    display.println("Connection Err");
    return;
  }
  display.println(&timeinfo, "%H:%M:%S");             // display time

  display.fillRect(10, 35, 108, 20, SSD1306_BLACK);
  display.setTextSize(1);
  display.setCursor(20, 40);
  display.print(&timeinfo, "%a %d %b %Y");            // display date
}