#include <math.h>
#include <LiquidCrystal.h>

#define NTC1 A0
#define NTC2 A1
#define NTC3 A2

template<int samplesNum>
class AverageFilter
{
  public:
  AverageFilter(int pin)
  {
    pinIn = pin;
  }

  int operator()()
  {
    sum -= samples[curIndex];
    samples[curIndex] = analogRead(pinIn);
    sum += samples[curIndex];
    curIndex = (curIndex + 1) % samplesNum;  
    
    return sum/samplesNum;
  }

  private:
  int pinIn;
  double sum = 0;
  double samples[samplesNum]{};
  int curIndex = 0;
};

LiquidCrystal lcd(13, 12, 11, 10, 9, 8);

AverageFilter<10> filter1(NTC1);
AverageFilter<10> filter2(NTC2);
AverageFilter<10> filter3(NTC3);

void process()
{
const float BETA = 3950;
int analogValue1 = filter1();
int analogValue2 = filter2();
int analogValue3 = filter3();
//пересчет в градусы
float celsius1 = 1 / (log(1 / (1023. / analogValue1 - 1)) / BETA + 1.0 / 298.15) - 273.15;
float celsius2 = 1 / (log(1 / (1023. / analogValue2 - 1)) / BETA + 1.0 / 298.15) - 273.15;
float celsius3 = 1 / (log(1 / (1023. / analogValue3 - 1)) / BETA + 1.0 / 298.15) - 273.15;
//расчет минимального, максимального, среднего значений
int minVal = round(min(celsius1, min(celsius2, celsius3)));
int maxVal = round(max(celsius1, max(celsius2, celsius3)));
int avgVal = round((celsius1 + celsius2 + celsius3)/3);

//преобразование в char и вывод на дисплей
const int kSize = 4;
char bufer[kSize];

lcd.setCursor(0,1);
dtostrf(minVal, -1, 0, bufer);
print(bufer, kSize);

lcd.setCursor(5,1);
dtostrf(avgVal, -1, 0, bufer);
print(bufer, kSize);

lcd.setCursor(10,1);
dtostrf(maxVal, -1, 0, bufer);
print(bufer, kSize);
}

//вспомогательная функция печати на дисплей, чтобы не выполнять clear каждый новый цикл (защита от мерцания)
void print(char *bufer, int size)
{
  bool endString = false;
  for(int i = 0; i < size; ++i)
  {
    if (bufer[i] == '\0')
    {
      endString = true;
    }
    if(endString)
    {
      lcd.print(" ");
    }    
    else
    {
      lcd.print(bufer[i]);
    }    
  }
}

void setup() 
{
  pinMode(NTC1, INPUT);
  pinMode(NTC2, INPUT);
  pinMode(NTC3, INPUT);
  analogReference(DEFAULT);
  lcd.begin(16, 2, LCD_5x8DOTS);
  lcd.clear();
  lcd.print("MIN  AVG  MAX");
}

void loop() 
{
  process();  
  delay(100);
}