#include <DHTesp.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <WiFi.h>
#include <PubSubClient.h>

#define DHT_PIN 14        // DHT22 Pin
#define DHT_TYPE DHTesp::DHT22 // DHT22 Type
#define PIR_PIN 15        // PIR pin
#define LED_PIN 12        // LED pin
#define LCD_ADDR 0x27   // Address I2C of LCD

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.emqx.io";
int port = 1883;
char clientId[100];

DHTesp dht;
WiFiClient espClient;
PubSubClient client(espClient);

LiquidCrystal_I2C lcd(LCD_ADDR, 16, 2);

void setup() {
  //setup serial
  Serial.begin(115200);
  Serial.print("Collecting data...");

  //setup LCD init
  lcd.init();
  lcd.backlight();
  lcd.setCursor(1, 0);
  lcd.print("Collecting data...");
  delay(1000);

  //setup DHT and PIR sensor
  dht.setup(DHT_PIN, DHT_TYPE);
  pinMode(PIR_PIN, INPUT);
  //config LED_PIN output
  pinMode(LED_PIN, OUTPUT);

  //infor connecting to broker
  delay(100);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  wifiConnect();  //connect to wifi
  //set up MQTT
  client.setServer(mqttServer, port);
  client.setCallback(callback);
}

void wifiConnect() {
  //Connect to wifi network
  Serial.print("Connecting to WiFi ");
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print("...");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void mqttConnect() {
  while (!client.connected()) {
    Serial.print("\nConnecting to MQTT Broker...");
    long r = random(1000);
    sprintf(clientId, "\nESP32ClientId - %ld", r);
    if (client.connect(clientId)) {
      Serial.print(clientId);
      Serial.println(" connected!");
      client.subscribe("ESP32/led");
    } else {
      Serial.print("Failed!, ");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("\nMessage arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  String stPayload;
  
  //read string from payload received
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    stPayload += (char)payload[i];
  }
  Serial.println();
  // control LED on/off accordingly to the received data
  //payload: ON, LED ON, otherwise ...
  if (String(topic) == "ESP32/led") {
    Serial.print("LED changing to ");
    if(stPayload == "ON"){
      Serial.println("ON");
      digitalWrite(LED_PIN, HIGH);
    }
    else if(stPayload == "OFF"){
      Serial.println("OFF");
      digitalWrite(LED_PIN, LOW);
    }
  }
}

void loop() {
  // get data from sensors
  float temperature = dht.getTemperature();
  float humidity = dht.getHumidity();

  int packNo = random(1000);
  String payload = "{\"PackNo\": " + String(packNo) + ", \"temperature\": " + String(temperature) + ", \"humidity\": " + String(humidity) + "}";
  
  // Connect with MQTT broker
  if (!client.connected()) {
    mqttConnect();
  }
  client.loop();

  char tempStr[10];
  char humStr[10];

  // Format data
  sprintf(tempStr, "%.2f C", temperature);
  sprintf(humStr, "%.2f %%", humidity);

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Temp: ");
  lcd.print(tempStr);
  lcd.setCursor(0, 1);
  lcd.print("Humidity: ");
  lcd.print(humStr);

  // Read and write data
  Serial.print("\nTemperature: ");
  Serial.print(temperature);
  Serial.print(" C\nHumidity: ");
  Serial.print(humidity);
  Serial.println(" %");

  //Publish the payload to MQTT topic
  client.publish("ESP32/sensor_data", payload.c_str());
  Serial.print("Data sent to broker!");
  Serial.print("\n------------------");

  delay(10000);  // Time delay 10s
}