#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <DHT.h>

const int redPin = 11;    // Red pin of the RGB LED
const int greenPin = 10;  // Green pin of the RGB LED
const int bluePin = 9;   // Blue pin of the RGB LED

#define DHTPIN 13
#define DHTTYPE DHT11
DHT dht(DHTPIN, DHTTYPE);

const int buttonPin = 6;  // Pin for the push-button

bool systemOn = false;  // Variable to track whether the system is on or off

#define DEBUG_MODE  // Comment out this line to disable serial output

// Function to set the RGB LED color based on the temperature
void setLedColor(float temperatureF) {
  int redValue = 0;
  int greenValue = 0;
  int blueValue = 0;

  if (temperatureF < 50) {
    // Blue gradient for temperatures under 50°F
    blueValue = map(temperatureF, -20, 50, 255, 0);
  } else {
    // Red gradient for temperatures 50°F and above
    redValue = map(temperatureF, 50, 100, 0, 255);
  }

  analogWrite(redPin, redValue);
  analogWrite(greenPin, greenValue);
  analogWrite(bluePin, blueValue);
}

// Create an LCD object with I2C address 0x27 (use your actual I2C address if different)
LiquidCrystal_I2C lcd(0x27, 16, 2);

bool checkButton() {
  static bool oldBtnState = true; // INPUT_PULLUP idles high

  bool isButtonPressed = false;
  int btnState = digitalRead(buttonPin);
  if (btnState != oldBtnState) {
    oldBtnState = btnState;
    if (btnState == LOW) {
      isButtonPressed = true;
      Serial.println("Button pressed");
    } else {
      Serial.println("Button released");
    }
    delay(20);  // for debounce
  }
  return isButtonPressed;
}

void setup() {
  lcd.init();
  lcd.backlight();
  lcd.print("System OFF");
  dht.begin();

#ifdef DEBUG_MODE
  Serial.begin(9600);  // Initialize Serial communication
#endif

  pinMode(redPin, OUTPUT);
  pinMode(greenPin, OUTPUT);
  pinMode(bluePin, OUTPUT);
  pinMode(buttonPin, INPUT_PULLUP);
}

void loop() {
  // Check if the button is pressed
  if (checkButton()) {
    // Toggle the system on/off
    systemOn = !systemOn;

    // Display the system state on the LCD without clearing
    lcd.setCursor(0, 0);
    lcd.print(systemOn ? "System ON       " : "System OFF      ");

    lcd.setCursor(0, 1);
    lcd.print(systemOn ? "                " : "                ");

    // Display dash lines if turning off after being on
    if (!systemOn) {
      #ifdef DEBUG_MODE
        Serial.println("-----------------");
      #endif
    }

    delay(500);  // Add a small delay for debouncing
  }

  // If the system is on, proceed with temperature and humidity sensing
  if (systemOn) {
    delay(2000);

    float temperatureCelsius = dht.readTemperature(); // Read temperature in Celsius
    float humidity = dht.readHumidity(); // Read humidity

#ifdef DEBUG_MODE
    if (isnan(temperatureCelsius) || isnan(humidity)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
    }

    // Convert Celsius to Fahrenheit for serial output
    float temperatureFahrenheit = dht.readTemperature(true);

    Serial.print("Temperature: ");
    Serial.print(temperatureFahrenheit);
    Serial.print(" °F, Humidity: ");
    Serial.print(humidity);
    Serial.println(" %");
#endif

// Use sprintf to format the temperature and humidity values
    char tempString[17];
    char humidityString[17];
    char scale = 'F';
    sprintf(tempString, "Temp: %8d%c%c", (int)(temperatureFahrenheit + 0.5), char(223), scale);
    sprintf(humidityString, "Humidity: %5d%%", (int)(humidity + 0.5));

    // Print the formatted values directly to the LCD
    lcd.setCursor(0, 0);
    lcd.print(tempString);
    lcd.setCursor(0, 1);
    lcd.print(humidityString);

    // Set LED color based on temperature
    setLedColor(temperatureFahrenheit);
  } else {
    // If the system is off, turn off the LED
    analogWrite(redPin, 0);
    analogWrite(greenPin, 0);
    analogWrite(bluePin, 0);
  }
}