#include <WiFi.h>
#include <PubSubClient.h>
#include <DHTesp.h>
#include <ESP32Servo.h>
#include <FastLED.h>
#include <Adafruit_SSD1306.h>
#include <Wire.h>
#include "RTClib.h"

#define LED_PIN 4 // Pin strip LED WS2812
#define NUM_LEDS 16 // Jumlah LED dalam strip

CRGB leds[NUM_LEDS];
Servo myservo; // objek servo

const int DHT_PIN = 15;
DHTesp dht;

RTC_DS3231 rtc; // rtc class

const char *ssid = "Wokwi-GUEST";
const char *password = "";
const char *mqtt_server = "test.mosquitto.org";

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

char daysOfTheWeek[7][12] = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"};

void setup_wifi()
{
  delay(10);
  Serial.println();
  Serial.print("Menghubungkan ke ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi terhubung");
  Serial.println("Alamat IP: ");
  Serial.println(WiFi.localIP());
}

void callback(char *topic, byte *payload, unsigned int length)
{
  String string;
  Serial.print("Pesan diterima [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++)
  {
    string += ((char)payload[i]);
  }
  Serial.print(string);

  if (strcmp(topic, "/ThinkIOT/temp") == 0)
  {
    // Menangani data suhu di sini
    float temperature = string.toFloat();
    // Lakukan sesuatu dengan data suhu
  }
  else if (strcmp(topic, "/ThinkIOT/hum") == 0)
  {
    // Menangani data kelembaban di sini
    float humidity = string.toFloat();
    // Lakukan sesuatu dengan data kelembaban
  }

  if (strcmp(topic, "/ThinkIOT/Servo-nodered/bro") == 0)
  {
    // Menangani data kontrol servo di sini
    int status = string.toInt();
    int pos = map(status, 1, 100, 0, 180);
    Serial.println(pos);
    myservo.write(pos);
    delay(15);
  }

  if (strcmp(topic, "lights/neopixel") == 0)
  {
    int red, green, blue;
    sscanf(string.c_str(), "%d,%d,%d", &red, &green, &blue);
    Serial.print("Mengatur warna NeoPixel ke (R,G,B): ");
    Serial.print(red);
    Serial.print(",");
    Serial.print(green);
    Serial.print(",");
    Serial.println(blue);
    fill_solid(leds, NUM_LEDS, CRGB(red, green, blue));
    FastLED.show();
  }

  if (strcmp(topic, "oled/display") == 0)
  {
    // Menangani pesan untuk OLED display
    updateDisplay(string);
  }
}

void updateDisplay(String message)
{
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 0);

  if (message != "")
  {
    // Menampilkan pesan dari MQTT
    display.println(message);
  }
  else
  {
    // Menampilkan jam digital ketika tidak ada data dari MQTT
    displayTime();

    // Menampilkan data suhu & kelembapan
    displayTempAndHum();
  }

  display.display();
}

void displayTime()
{
  DateTime now = rtc.now();
  display.clearDisplay();

  display.setTextSize(1);                // Normal 1:1 pixel scale
  display.setCursor(0, 0);
  display.setTextColor(SSD1306_WHITE); // Draw white text
  display.print("");
  display.setCursor(15, 15); // Start at top-left corner
  display.print(now.year(), DEC);
  display.print('/');
  display.print(now.month(), DEC);
  display.print('/');
  display.print(now.day(), DEC);

  display.print(" ");

  display.print(daysOfTheWeek[now.dayOfTheWeek()]);
  display.println();
  display.println();
  display.setTextSize(2);
  display.print("  ");
  display.print(now.hour(), DEC);
  display.print(':');
  display.print(now.minute(), DEC);
  display.print(':');
  display.print(now.second(), DEC);
  display.println();

  display.display();
  delay(1000);
}

void displayTempAndHum()
{
  TempAndHumidity data = dht.getTempAndHumidity();
  String temp = String(data.temperature, 2);
  String hum = String(data.humidity, 1);

  // Menampilkan data suhu & kelembapan
  display.setTextSize(1);
  display.setCursor(0, 40);
  display.print("Temp: ");
  display.print(temp);
  display.print(" C");
  display.setCursor(0, 50);
  display.print("Humidity: ");
  display.print(hum);
  display.print(" %");
}

void reconnect()
{
  while (!client.connected())
  {
    Serial.print("Mencoba koneksi MQTT...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str()))
    {
      Serial.println("Terhubung");
      client.subscribe("/ThinkIOT/temp");
      client.subscribe("/ThinkIOT/hum");
      client.subscribe("/ThinkIOT/Servo-nodered/bro");
      client.subscribe("lights/neopixel");
      client.subscribe("oled/display");
    }
    else
    {
      Serial.print("gagal, rc=");
      Serial.print(client.state());
      Serial.println(" coba lagi dalam 5 detik");
      delay(5000);
    }
  }
}

void setup()
{
  pinMode(2, OUTPUT);
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  dht.setup(DHT_PIN, DHTesp::DHT22);
  myservo.attach(5);

  // Setup strip LED WS2812
  FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS);

  // Setup OLED display
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.clearDisplay();

  // RTC setup
  if (!rtc.begin())
  {
    Serial.println("Couldn't find RTC");
    while (1)
      ;
  }

  if (rtc.lostPower())
  {
    Serial.println("RTC lost power, lets set the time!");
    rtc.adjust(DateTime(F(__DATE__), F(__TIME__))); // set time from computer time
  }
}

void loop()
{
  if (!client.connected())
  {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 2000)
  {
    lastMsg = now;
    TempAndHumidity data = dht.getTempAndHumidity();

    String temp = String(data.temperature, 2);
    client.publish("/ThinkIOT/temp", temp.c_str());

    String hum = String(data.humidity, 1);
    client.publish("/ThinkIOT/hum", hum.c_str());

    Serial.print("Suhu: ");
    Serial.println(temp);
    Serial.print("Kelembaban: ");
    Serial.println(hum);
  }
}