#include <LiquidCrystal_I2C.h>
#include "DHTesp.h"
#include <WiFi.h>
#include <HTTPClient.h>
#include <ArduinoJson.h>
#include <PubSubClient.h>

LiquidCrystal_I2C lcd(0x27, 20, 4); // Khởi tạo màn hình LCD

#define DHT_PIN 15
#define LED_PIN 26
#define PIR_PIN 13

const char* mqtt_server = "broker.hivemq.com"; // Máy chủ MQTT

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE	(50)
char msg[MSG_BUFFER_SIZE];
int value = 0;

// Hàm callback được gọi khi nhận được thông điệp từ máy chủ MQTT
void callback(char* topic, byte* payload, unsigned int length) {
  // Xử lý dữ liệu nhận được từ MQTT
  // Ở đây, nếu nhận được '1', thì bật đèn LED, ngược lại tắt đèn LED
  if ((char)payload[0] == '1') {
    digitalWrite(LED_PIN, LOW); // Bật đèn LED
  } else {
    digitalWrite(LED_PIN, HIGH); // Tắt đèn LED
  }
}

// Kết nối MQTT
void reconnect() {
  while (!client.connected()) {
    Serial.print("MQTT connection...");
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      client.publish("/IOT/64", "Connected");
      client.subscribe("/IOT/64");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

DHTesp dhtSensor;

void setup() {
  Serial.begin(115200);                       // Khởi tạo giao tiếp serial với baud rate là 115200.
  WiFi.begin("Wokwi-GUEST", "", 6);           // Bắt đầu quá trình kết nối WiFi 
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);    // Khởi tạo cảm biến DHT22 và cấu hình nó

  pinMode(LED_PIN, OUTPUT);                   // Đặt chân OUTPUT
  pinMode(PIR_PIN, INPUT);                    // Đặt chân INPUT
  
  client.setServer(mqtt_server, 1883);        // Thiết lập máy chủ MQTT
  client.setCallback(callback);               // Thiết lập hàm callback mà Arduino sẽ gọi khi nhận được thông điệp từ máy chủ MQTT.
  lcd.init();                                 // Khởi tạo LCD
  lcd.backlight();                            // Bật đèn nền LCD
}

void loop() {
  if (!client.connected()) {                  // Kiểm tra kết nối
    reconnect(); 
  }
  
  client.loop();                                          // Lắng nghe các thông điệp MQTT
  TempAndHumidity data = dhtSensor.getTempAndHumidity();  // Đọc dữ liệu từ cảm biến DHT22
  int temp = data.temperature;                            
  int humid = data.humidity; 
  
  // Hiển thị lên LCD
  lcd.setCursor(0, 0);
  lcd.print("Temp:" + String(temp) + "C");
  lcd.setCursor(0, 1);
  lcd.print("Humidity:" + String(humid) + "%");
  
  // Tạo chuỗi thông điệp MQTT
  String mg = "Temp: " + String(temp) + "C  Humidity: " + String(humid) + "%";
  unsigned long now = millis();
  ++value;
  char valueStr[10];
  snprintf(valueStr, sizeof(valueStr), "%d", value);
  mg += " Value: ";
  mg += valueStr;
  char msg[MSG_BUFFER_SIZE];
  mg.toCharArray(msg, MSG_BUFFER_SIZE);
  
  // Publisher MQTT
  Serial.print("Publish message: ");
  Serial.println(msg);
  client.publish("/IOT/35", msg);
  delay(3000);
}