#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <WiFi.h>
#include <PubSubClient.h>

// I2C LCD configuration
LiquidCrystal_I2C lcd(0x27, 16, 2); // Adjust the I2C address as needed

// MQTT configuration
const char *ssid = "Wokwi-GUEST";
const char *password = "";  // No password for "Wokwi-GUEST"
const char *mqtt_server = "broker.emqx.io";
const char *topic = "parking/status";

WiFiClient espClient;
PubSubClient client(espClient);

void setup()
{
  Serial.begin(115200);
 Wire.begin(21, 22);
  // I2C LCD setup
  lcd.begin(16, 2);
  lcd.backlight();
  lcd.setCursor(0, 0);
  lcd.print("Parking Status:");

  // WiFi setup
  connectWiFi();

  // MQTT setup
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  connectMQTT();
}

void connectWiFi()
{
  Serial.println("Connecting to WiFi");
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void connectMQTT()
{
  while (!client.connected())
  {
    Serial.println("Connecting to MQTT...");
    if (client.connect("ESP32Client"))
    {
      Serial.println("connected to MQTT");
      client.subscribe(topic);
    }
    else
    {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" retrying in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char *topic, byte *payload, unsigned int length)
{
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);

  String message = "";
  for (int i = 0; i < length; i++)
  {
    message += (char)payload[i];
  }

  lcd.setCursor(0, 1);
  lcd.print(message);

  Serial.println(message);
}

void loop()
{
  if (!client.connected())
  {
    connectMQTT();
  }
  client.loop();
}