#include <WiFi.h>
#include "PubSubClient.h"
#include <WebServer.h>
#include <ArduinoJson.h>


//kết nối tới máy chủ MQTT và cấu hình các chủ đề và ID của MQTT client.
const char *MQTTServer = "broker.emqx.io";
const char *MQTT_Topic = "deployment-j6001808";
const char *MQTT_ID = "deployment-j6001808"; // Đặt MQTT Client ID
int Port = 1883;
//Khai báo các biến như espClient, client
// (thuộc lớp PubSubClient) và khai báo các chân GPIO dành cho ba đèn LED.
WiFiClient espClient;
PubSubClient client(espClient);
const int redPin = 2;
const int yellowPin = 4;
const int greenPin = 5;
int maudo = 0;
int mauxanh = 0;
int mauvang = 0;


//ket noi wifi
void WIFIConnect() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", ""); // Thêm mật khẩu WiFi ở đây
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected, IP address: ");
  Serial.println(WiFi.localIP());
}

void MQTT_Reconnect() {
  while (!client.connected()) {
    if (client.connect(MQTT_ID)) {
      Serial.print("MQTT Client: ");
      Serial.print(MQTT_ID);
      Serial.println(" connected");
      client.subscribe(MQTT_Topic);
    } else {
      Serial.print("MQTT connection failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

//hàm callback được sử dụng trong thư viện PubSubClient để 
//xử lý thông điệp nhận được từ máy chủ MQTT khi có sự kiện message arrived
// (thông điệp đã đến).
void callback(char *topic, byte *message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  String stMessage;

  for (int i = 0; i < length; i++) {
    // In ra từng byte của message nhận được trên cổng Serial
    Serial.print((char)message[i]);
    // Lưu từng byte vào biến stMessage dưới dạng chuỗi ký tự
    stMessage += (char)message[i];
}

// Tạo một biến đối tượng JSON có tên là doc với kích thước tối đa 200 bytes
StaticJsonDocument<200> doc;
// Phân tích chuỗi JSON từ stMessage và lưu vào biến doc
DeserializationError err = deserializeJson(doc, stMessage);

if (!err) {
    // Gán giá trị từ JSON cho các biến tương ứng: mauvang, mauxanh, maudo
    mauvang = doc["vang"];
    mauxanh = doc["xanh"];
    maudo = doc["do"];
} else {
    // Nếu phân tích JSON thất bại, in ra thông báo lỗi
    Serial.print("JSON parsing failed: ");
    Serial.println(err.c_str());
}

// Gửi một thông điệp "Thanh cong" tới chủ đề MQTT
client.publish(MQTT_Topic, "Thanh cong");

// In ra giá trị của các biến: maudo, mauvang, mauxanh trên cổng Serial để kiểm tra
Serial.print("maudo: ");
Serial.println(maudo);
Serial.print("mauvang: ");
Serial.println(mauvang);
Serial.print("mauxanh: ");
Serial.println(mauxanh);

}

void setup() {
  Serial.begin(115200);
  WIFIConnect();
  client.setServer(MQTTServer, Port);
  client.setCallback(callback);
  pinMode(redPin, OUTPUT);
  pinMode(yellowPin, OUTPUT);
  pinMode(greenPin, OUTPUT);
}

void loop() {
  delay(10);
  if (mauvang) {
    digitalWrite(yellowPin, HIGH);
    delay(mauvang);
    digitalWrite(yellowPin, LOW);
  }

  if (mauxanh) {
    digitalWrite(greenPin, HIGH);
    delay(mauxanh);
    digitalWrite(greenPin, LOW);
  }

  if (maudo) {
    digitalWrite(redPin, HIGH);
    delay(maudo);
    digitalWrite(redPin, LOW);
  }
  if (WiFi.status() == WL_CONNECTED) { //đảm bảo rằng ESP32 đang kết nối với mạng Wi-Fi.
    if (!client.connected()) { //chương trình sẽ kiểm tra xem nó có kết nối với máy chủ MQTT không
      MQTT_Reconnect();//thực hiện kết nối lại với máy chủ MQTT.
    }
    client.loop(); //duy trì kết nối MQTT và xử lý các gói tin MQTT đến.
  }
}