/**
  Arduino Uno - NeoPixel HSV Potentiometer Circle Rotation With Gamma Correction
  v. 1.0
  Copyright (C) 2018 Robert Ulbricht
  https://www.arduinoslovakia.eu

  IDE: 1.8.5 or higher
  Board: Arduino or Arduino Pro Mini

  Libraries
  NeoPixel: https://github.com/adafruit/Adafruit_NeoPixel
  Function setPixelColorHsv is extracted from pull request
  https://github.com/adafruit/Adafruit_NeoPixel/pull/114

  HSV
  https://en.wikipedia.org/wiki/HSL_and_HSV

  This program is free software: you can redistribute it and/or modify
  it under the terms of the GNU General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  This program is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU General Public License for more details.

  You should have received a copy of the GNU General Public License
  along with this program.  If not, see <http://www.gnu.org/licenses/>.
*/

#include <Adafruit_NeoPixel.h>
#include "hsv.h"

// data pin
#define PIN 32
// led count
#define CNT 16
// max Hue
#define MAXHUE 256*6

int position = 0;
int pot_hue;        // A0
int pot_saturation; // A2
int pot_speed;      // A3
char output[128];
unsigned long next_time = 0;

Adafruit_NeoPixel strip = Adafruit_NeoPixel(CNT, PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  Serial.begin(115200);
  strip.begin();
}

void loop() {
  // analog
  pot_hue = map(aRead(33), 0, 1023, 0, MAXHUE);
  pot_saturation = map(aRead(34), 0, 1023, 0, 255);
  pot_speed = map(aRead(35), 0, 1023, 1, 500);
  unsigned long m = millis();
  if (m - next_time > 1000L) {
    next_time = m;
    sprintf(output, "hue: %d, sat: %d, spd: %d", pot_hue, pot_saturation, pot_speed);
    Serial.println(output);
  }

  // hue - red
  // saturation - max
  // value - 0-255
  for (int i = 0; i < CNT; i++)
    strip.setPixelColor((i + position) % CNT,
                        getPixelColorHsv(i,
                                         pot_hue,
                                         pot_saturation,
                                         strip.gamma8(i * (255 / CNT))));
  strip.show();
  position++;
  position %= CNT;
  delay(pot_speed);
}

int aRead(int anl) {
  long tmp = 0, t;
  // discard first X measurements
  for (int i = 0; i < 1; i++)
    analogRead(anl);
  for (int i = 0; i < 4; i++) {
    t = analogRead(anl);
    tmp += t;
  }
  return tmp / 4;
}